I need a way to rename all files in folders and subfolders to lowercase.
I'd like to know if there is a way to do that using only windows (XP or 7)
I need a way to rename all files in folders and subfolders to lowercase.
I'd like to know if there is a way to do that using only windows (XP or 7)
Go to the directory and run the following command:
for /f "Tokens=*" %f in ('dir /l/b/a-d') do (rename "%f" "%f")
Here is the break-down in case someone wants to modify/improve :
for /f
- For every line"Tokens=*"
- Process each item in every line.%f in (...)
- %f
is your variable name for every item.dir
- lists every file and subdirectory in a directory./l
- (parameter for dir) Uses lowercase./b
- (parameter for dir) Uses bare format, only the file/directory names, no size, no headers./a-d
- (parameter for dir) Do not list directories. (a
stands for attribute
, -
stands for not
and d
stands for directory
).rename "%f" "%f"
- rename the file with its own name, which is actually lowercased by the dir
command and /l
combination.for /f "Tokens=*" %f in ('dir /l/b/a-d/s') do (rename "%f" "%f")
(added /r to dir).
Since Windows 7 you could use PowerShell for those tasks
Get-ChildItem "C:\path\to\folder" -recurse |
Where {-Not $_.PSIsContainer} |
Rename-Item -NewName {$_.FullName.ToLower()}
- Choose your root folder
- all files inside root folder and subfolders are renamed
- folder names are excluded with Where {-Not $_.PSIsContainer} |
spacetornado Renamer is a Windows program that renames mass amounts of files in batches. You can search and replace text, remove a certain number of characters, change the case to lower, upper or First Letter Capital, and add text to the beginning or end (append/prepend) of every filename
Here is a proper recursive command line solution using only native cmd.exe commands that actually works. I believe it is the simplest possible native solution:
for /r %D in (.) do @for /f "eol=: delims=" %F in ('dir /l/b/a-d "%D"') do @ren "%D\%F" "%F"
If you are willing to go beyond native cmd.exe commands, then another option is my JREN.BAT regular expression renaming utility that supports options to convert names to upper or lower case. It is pure script (hybrid JScript/batch) that runs natively on any Windows machine from XP onward - no 3rd party exe files needed. Full documentation is built in - accessed from the command line via jren /?
, or jren /??
if you want paged output.
With JREN, the recursive solution is as simple as:
jren "^" "" /s /l
/a-d
switch and it will also lowercase the folder names too.
" D"') was unexpected at this time.
Running it as a direct command works fine, just doesn't work when run as a batch file. Not sure as to how to make it work as a batch file, but thought I'd give heads up to the issue.
Apr 12, 2018 at 17:49
%D
must change to %%D
, and %F
to %%F
if you put the command within a batch script.
for /f "Tokens=*" %f in ('cmd /c "echo %cd%& dir /l/b/ad/s"') do (for /f "Tokens=*" %g in ('dir /l/b/a-d "%f"') do (rename "%f"\"%g" "%g"))
for /f "Tokens=*" %f in ('cmd /c "echo %cd%& dir /l/b/ad/s"')
Gets a list of the absolute paths of all the directories inside the current (including it):
C:\Foo>
C:\Foo\TO.txt
C:\Foo\Bar\LOWER.txt
C:\Foo\Bar\Baz\CASE.txt
for /f "Tokens=*" %g in ('dir /l/b/a-d "%f"') do (rename "%f"\"%g" "%g")
Gets a list of all the file names (or file and directory names if you take out the /a-d
switch) inside each of the absolute paths found by the first loop, and converts the name of these files to lowercase.
C:\Foo\TO.txt
C:\Foo\Bar\LOWER.txt
C:\Foo\Bar\Baz\CASE.txt
* it needs two loops because the second argument to rename
must be a file name and not an absolute path (as the one obtained by the /s
switch).
cmd /c "echo %cd%&
in the first for
? It is completely unnecessary.
echo %cd%
is there to add the current folder to the list of absolute paths; and cmd /c
makes &
work to combine commands. I'm a total noob regarding Windows Batch Scripting; if you know of a better way, feel free to improve the answer!
May 7, 2016 at 11:19
My personal favorite batch file-renaming utility is Cylog's WildRename. Among many other features, it can change the case of filenames. The best thing about WildRename is probably that it supports regular-expressions!
You could use a "character replacement" strategy...
set Name=%Name:A=a%
set Name=%Name:B=b%
set Name=%Name:C=c%
...and so on, for letters A-Z. You could probably implement it in the form of a FOR loop.
Powershell
Navigate to the dir and run:
dir | Rename-Item -NewName { $_.Name.ToLowerInvariant() }
I have verified that this works. Found here: http://www.hanselman.com/blog/PennyPinchingVideoMovingMyWebsitesImagesToTheAzureCDNAndUsingACustomDomain.aspx
http://www.dostips.com/DtCodeCmdLib.php#Function.toLower gives a simple function that you should be able to include and call from a batch file.
So have the batch file iterate over the folders/filenames, and call this function to generate the lowercase version of the name.
From http://windowsitpro.com/articles/index.cfm?articleid=81612:
Using only standard commands, I have scripted LwrCase.bat and LwrCase_Folder.bat, to rename a file name to lower case, or rename all file names in a folder to lower case.
To rename a file name to lower case, use:
[call] LwrCase FullyQualifiedFileName
Where FullyQualifiedFileName is the fully qualified file name to be renamed.
To rename all the files names in a directory, use:
[call] LwrCase_Folder FullyQualifiedDirectoryName [/S]
where FullyQualifiedDirectoryName is the fully qualify folder path, and /S is an optional parameter that will also rename files names in all sub-folders.
NOTE: LwrCase.bat makes use the the /L switch of the DIR command, which returns lower case names.
LwrCase.bat contains:
@echo off
if {%1}=={} @echo Syntax: LwrCase FullyQualifiedFileName&goto :EOF
if not exist %1 @echo LwrCase - %1 NOT found.&goto :EOF
setlocal
for /f "Tokens=*" %%a in ('@echo %~a1') do (
set file=%%a
)
if /i "%file:~0,1%" EQU "d" @echo LwrCase - %1 is NOT a file.&endlocal&goto :EOF
for /f "Tokens=*" %%f in ('dir %1 /L /b /a /a-d') do (
Rename %1 "%%f"
)
endlocal
LwrCase_Folder.bat contains:
@echo off
if {%1}=={} @echo Syntax: LwrCase_Folder FullyQualifiedDirectoryName&goto :EOF
if not exist %1 @echo LwrCase_Folder - %1 NOT found.&goto :EOF
setlocal
for /f "Tokens=*" %%a in ('@echo %~a1') do (
set folder=%%a
)
if /i "%folder:~0,1%" NEQ "d" @echo LwrCase_Folder - %1 is NOT a folder.&endlocal&goto :EOF
pushd %1
set sw=/B /A /A-D
if /i {%2}=={/S} set sw=%sw% %2
for /f "Tokens=*" %%f in ('dir %sw%') do (
call LwrCase "%%f"
)
popd
endlocal
The best program for doing this in Windows is Bulk Rename Utility. It is a mans tool. You can even use regex to rename files and/or folders. It also has shell integration (so you can execute from explorer with a right click) which is very nice. 64 bit and 32 bit versions available.
The accepted answer to this question, by loftysnake,
works for the current directory but does not search subfolders.
Sawny suggested a simple modification to loftysnake’s answer
to make it recursive, but it doesn’t work,
because, while the rename
command
allows you to specify a drive and path with filename1 (the source),
filename2 (the destination) must be just a filename.
To quote the help (/?
) message,
… you cannot specify a new drive or path for your destination file.
But move
works where rename
does not,
so you can recursively rename files to lowercase with this command:
for /f "Tokens=*" %f in ('dir /l/b/a-d/s') do (move /y "%f" "%f")
because it turns out that Move
can cope with directory paths.
The above command works
when typed directly into the Command Prompt (CMD.EXE
).
If you want to do this from within a batch (.BAT
) file,
you must double the %
characters:
for /f "Tokens=*" %%f in ('dir /l/b/a-d/s') do (move /y "%%f" "%%f")
And you can probably leave off the parentheses and the /y
and say just do move …
.
move
worked where rename
does not, and I think I am the only one who has suggested the use of the move
command here. I simply took @loftysnake and @sawny s suggestions, and hopefully improved them a wee bit.
move
, but I can’t find it now.
May 30, 2017 at 19:13
Recursive solution. Put this into a recursiverename.cmd file..
for /f "Tokens=*" %%f in ('dir /l/b/a-d') do (rename "%%f" "%%f")
for /r /d %%x in (*) do (
pushd "%%x"
for /f "Tokens=*" %%f in ('dir /l/b/a-d') do (rename "%%f" "%%f")
popd
)