0

I want an filter or a rule that allows me to send bulk emails to around 200 recipients when an email is received from a specific address. For example, when the email client receives an email From [email protected], I want it to resend the email to all the people in my address book.

I tried to set rules in both Outlook and Thunderbird email clients, but the the only option I have is to "Forward", not to "Resend" or "Send" the email. there is an additional problem that all recipients appear in the address list. I want all addressees to be bcc.

Is there any way to do this?

1 Answer 1

2

You can create a rule to forward to a bcc'ed distribution list.

Edit 2015 02 23

While the above is technically true. It is not as simple as I thought. There is no bcc option in the dialog box for addresses when forwarding by rule. My version is 2010.

You can set a bcc in a rule with a run a script option rather than using the dialog box.

Option Explicit

Sub Forward_BCC_DL(item As Object)

Dim newForward As MailItem
Dim myRecipient As Recipient

If item.Class = olMail Then

    Set newForward = item.Forward

    Set myRecipient = newForward.Recipients.Add("Name of Distribution List with the quotes")
    myRecipient.Type = olBCC

    newForward.Recipients.ResolveAll
    newForward.Display  ' Comment out with a leading apostrophe once tested
    'newForward.Send    ' Remove leading apostrophe once tested

End If

ExitRoutine:
    Set newForward = Nothing
    Set myRecipient = Nothing

End Sub

Private Sub Forward_BCC_DL_Test()
' To test
'  open a message then run this code
Dim curritem As Object
Set curritem = ActiveInspector.currentItem
Forward_BCC_DL curritem
End Sub

If you are not familiar with VBA this will be helpful.

Getting Started with VBA in Outlook 2010

How to use Outlook's VBA Editor

Edit 2015 02 23 - End

Edit 2015 02 24

It is probably better to create a distribution list as used above but this will slowly retrieve all contacts.

Option Explicit

Sub Forward_BCC_All(mail As MailItem)

    Dim ContactsFolder As folder
    Dim Contact As Object
    Dim objMail As MailItem
    'Dim j As Long
    Dim objRecip As Recipient

    Set ContactsFolder = Session.GetDefaultFolder(olFolderContacts)

    Set objMail = mail.Forward
    'j = 0

    For Each Contact In ContactsFolder.Items

        'j = j + 1

        With objMail
            'Debug.Print j & ": " & Contact
            Set objRecip = .Recipients.Add(Contact)
            objRecip.Type = olBCC
        End With

    Next

    'Debug.Print "Resolving contacts slowly"

    objMail.Recipients.ResolveAll
    objMail.Display

ExitRoutine:
    Set objMail = Nothing
    Set ContactsFolder = Nothing
    Set Contact = Nothing

End Sub

Private Sub Forward_BCC_All_test()
Dim currItem As MailItem
Set currItem = ActiveInspector.currentItem
Forward_BCC_All currItem
End Sub

Edit 2015 02 24 - End

3
  • how could i forward to bcc'ed distribution list where the only option available that i can use in the rules is "forward it to people or distribution list" ?
    – Matt
    Feb 22, 2015 at 16:33
  • You should get the same dialog box as if you were forwarding manually. That dialog box has a BCC button.
    – niton
    Feb 22, 2015 at 16:55
  • i didn't see this option , could you post a screenshot ?
    – Matt
    Feb 23, 2015 at 16:24

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .