Can “~/” be re-bound to point somewhere else?

Question

I'm using Emacs on Windows XP and whenever I type in "~/" it automatically replaces that with a directory, in my case its "C:/Documents and Settings//Application Data". Is there any way I can get that to point to another directory like, say, my projects directory on the Desktop? Every time I need to make a new file there I have to C-x C-f + the full path, and although tab completion makes it faster than it'd normally be, it'd be nice to have that one directory bound to something like "~/" for easy access. Is there any way that could be done?

Answer 1

All you need to do is to set the %HOME% environmental variable.

This can be done by going to:
start->settings->control panel->system
Click on the advanced tab. At the bottom is a button: "Environmental Variables".

Create a new variable called HOME and put the path you want in there.

Since most windows programs don't care about this variable, it is unlikely to affect anything else for you.

This can also be done by editing the registry entries for emacs. Here is some information on the registry variables: Ms Windows Registry.

Answer 2

The ~ seems to be handled by expand-file-name, and it does not mention any way to change how it is expanded. But it does use the HOME environment variable. You could specify a new value for HOME, but that might confuse other things that use HOME as a place to store files (customize, etc. that might want to read from or write to files under HOME).

As an experiment, I wrote up some advice to find-file that temporarily changes the value of HOME. The idea is to minimize the amount of time where the alternate value is active.

(defvar fake-HOME-value "/var/tmp"
  "An alternate value to use for the HOME environment variable
while the 'fake-HOME' around advice is active.")

(defadvice find-file (around fake-HOME)
  "Temporarily replace the HOME environment variable with
the value from 'fake-HOME-value'."
  (let ((original-HOME-value (getenv "HOME")))
    (unwind-protect
        (progn
          (setenv "HOME" fake-HOME-value)
          ad-do-it)
      (setenv "HOME" original-HOME-value))))

(defun disable-fake-HOME ()
  "Disable the fake-HOME advice for find-file."
  (interactive)
  (progn
    (ad-disable-advice 'find-file 'around 'fake-HOME)
    (ad-update 'find-file)))

(defun enable-fake-HOME ()
  "Enable the fake-HOME advice for find-file."
  (interactive)
  (progn
    (ad-enable-advice 'find-file 'around 'fake-HOME)
    (if (ad-is-active 'find-file)
        (ad-update 'find-file)
      (ad-activate 'find-file))))

(enable-fake-HOME)
;(disable-fake-HOME)

Put it in your .emacs (or an .el file, and (load-file "/path/to/your.el")). I can not test it on Windows, but the only thing that is platform specific is the use of HOME, but I think Emacs converts the Windows equivalent (a combination of several environment variables?) to HOME.

Answer 3

~ is a very old and well established synonym for 'the user's home directory' and that logic is probably buried deep inside emacs and unlikely to change unless you're willing to rebuild it from source after finding the appropriate code and changing it. On the other hand, you could probably set your shortcut to start emacs to start in your chosen directory, allowing you to save and load files without specifying a path. Probably.