In Mac OS X Finder's column view, how do you show all columns, up to the list of volumes?

Question

In OS X's olden times, column view always allowed you to scroll left back to the list of volumes. In recent versions, however, the Finder will hide parents and ancestors.

For example, when you select a favorite "place" in the sidebar, no ancestors of that folder will be visitable without pressing Cmd+Up, but hitting Cmd+Up causes the current directory to lose focus, or disappear entirely, depending on the number of levels .

Clicking "Back" sends you back to the folder you were in, but it also re-hides all of its ancestors :(

I really wish I could see the entire hierarchy. Is that possible?

Answer 1

It is possible to create a new column view window that is rooted at the “list of volumes” through AppleScript. It can also copy the target and selection to the new window.

(*
 * Clone Finder window as column view rooted at “computer container”
 *
 * Create a new Finder window in column view mode rooted
 * at the “computer container” (list of mounted volumes) with
 * the selection, target, position, and bounds of the currently
 * active Finder window.
 *
 * BUGS
 *  - In list view, it is possible to make a selection that spans
 *      multiple folders. It is not possible to recreate this
 *      selection in column view (or icon view).
 *)
on run
    local oldWin, theSelection
    tell application "Finder"
        if not (exists Finder window 1) then return
        set oldWin to Finder window 1
        set theSelection to selection
        tell (make new Finder window with properties {target:computer container, current view:column view})
            set bounds to (get bounds of oldWin)
            set position to (get position of oldWin)
            set target to (get target of oldWin)
            activate
        end tell
        set selection to theSelection
        close oldWin
    end tell
end run

Copy the script into an AppleScript Editor (Script Editor prior to 10.6) document and save it in “script” or “script bundle” format.

You can use a launcher like FastScripts (or Quicksilver, etc.) to bind the script to a key for quick access. If you only want to run it every once in a while, you could just save it as ~/Scripts/Applications/Finder/Clone Finder window as column view rooted at “computer container”.scpt (or whatever name you like) and enable the script menu.

Answer 2

In Lion, the Finder's column view is "rooted" at the most recent folder (traversing back up the hierarchy) that appears in the Finder's sidebar.

For instance, if your home folder is in the sidebar (as it is by default), viewing any folder under it in column view will result in a column view that may only be scrolled left as far as said home folder. Remove the home folder from the column view, and you can go back up all the way to your hard disk volume ("Macintosh HD", by default). Remove that, and you can go all the way back to the "computer" view.

I can't verify whether it worked like this in recent versions of Snow Leopard as well, since I don't have a Snow Leopard machine available anymore.

Answer 3

No, there doesn't appear to be an option for this.

There may however be a way to change it with the ubiquitous default write that's becoming ever so popular.

Like you mentioned, simply moving to the parent folder will work, but you lose focus of the file.

Answer 4

Closest simple way to do this I can find is View > Show Path Bar.