Take the 2-minute tour ×
Super User is a question and answer site for computer enthusiasts and power users. It's 100% free, no registration required.

Possible Duplicate:
How to make Outlook 2010 not warn on empty subject?

Someone has asked this, but I never saw an answer:

Is there a setting to STOP warning me on empty subject line?

share|improve this question

marked as duplicate by Tom Wijsman, Arjan, BinaryMisfit Jan 21 '11 at 11:42

This question has been asked before and already has an answer. If those answers do not fully address your question, please ask a new question.

2  
I would have clicked "Close as duplicate", but TomWij's answer is really worth reading. –  grawity Jun 19 '10 at 19:23

1 Answer 1

Update: Actually, by a bump to this question and by "someone has asked this" I looked for duplicates:

How to make Outlook 2010 not wark me on an empty subject line?

It does answer the question:

Option Explicit

'=========================================================================
' Prevents Outlook® 2010 to display a no-subject warning message
' (c) Peter Marchert - http://www.outlook-stuff.com
' 2010-07-15 Version 1.0.0
' 2010-07-19 Version 1.0.1
'=========================================================================

Private WithEvents colInspectors As Outlook.Inspectors

Private Sub Application_Startup()

    '---------------------------------------------------------------------
    ' Set a reference to all forms
    '---------------------------------------------------------------------
    Set colInspectors = Outlook.Inspectors

End Sub

Private Sub colInspectors_NewInspector(ByVal Inspector As Inspector)

    '---------------------------------------------------------------------
    ' This code is running if a form (e. g. an e-mail) will be opened
    '---------------------------------------------------------------------

    Dim objItem As Object

    '---------------------------------------------------------------------
    ' Skip errors
    '---------------------------------------------------------------------
    On Error GoTo ExitProc

    '---------------------------------------------------------------------
    ' Set a reference to the open item
    '---------------------------------------------------------------------
    Set objItem = Inspector.CurrentItem

    '---------------------------------------------------------------------
    ' A new item does not have a received time
    '---------------------------------------------------------------------
    If Year(objItem.ReceivedTime) = 4501 Then

        '-----------------------------------------------------------------
        ' Check if the subject is empty if an e-mail was created by a
        ' template with predefined subject.
        '-----------------------------------------------------------------
        If objItem.Subject = "" Then objItem.Subject = " "

    End If

    ExitProc:

    '---------------------------------------------------------------------
    ' Delete the reference to the form and to the item
    '---------------------------------------------------------------------
    Set objItem = Nothing
    Set Inspector = Nothing

End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)

    On Error Resume Next

    '---------------------------------------------------------------------
    ' If the blank still exists it will now be removed (Outlook®
    ' will this not recognize)
    '---------------------------------------------------------------------
    Item.Subject = Trim(Item.Subject)

End Sub

Private Sub Application_Quit()

    '---------------------------------------------------------------------
    ' Delete the reference to the forms
    '---------------------------------------------------------------------
    Set colInspectors = Nothing

End Sub

Old answer, for a reference to the explanation of Microsoft's choice:

Why would one want to send a mail with an empty subject line? You send a mail with an intention and the subject is there to sum this up. Leaving the subject line empty increases the spam confidence level and your mail could thus be seen as junk.

Outlook was designed as a business-class or corporate e-mail client, not specifically for personal/home use. If you receive a lot of mails it is easier to scan through the subject lines than through the content bodies to determine what action to take for each mail...

Remarkable: A lot of users suffered from sending mails without a subject line so that they requested Microsoft to implement this behavior in Outlook 2010, you could request the option to switch this so they can implement it for the next service pack. Try the Microsoft customer service...

share|improve this answer
1  
What difference does it make why? The real question is why you wasted my time with this answer? –  Bob Jun 21 '10 at 11:47
2  
People upvoted this question so I'm not wasting your time with this answer, it indeed doesn't give a direct NO answer but does explain the reasoning behind it and it should be clear that there is no setting for it by just seeing the answer. In the other way I would have provided a direct way to change such a setting... This isn't a personal attack but just the reasons why such decisions have been made thus the absence of such an option leaving you with two options: Request the functionality or Accept the decisions. –  Tom Wijsman Jun 22 '10 at 22:43
1  
Excuse me for the incorrect tone set in that answer; it's meant as an helpful explanation, I never have the intent to insult online under this name. –  Tom Wijsman Jan 20 '11 at 21:31

Not the answer you're looking for? Browse other questions tagged or ask your own question.