Take the 2-minute tour ×
Super User is a question and answer site for computer enthusiasts and power users. It's 100% free, no registration required.

Examples...

This is happens in Office 2007/2010

In Windows Explorer, right click on file > Send To > Mail Recipient... This opens a modal new message window, I can't access anything else in outlook. So that bit of text from another email I wanted to copy/paste into the new email, can't.

In Excel, Send > E-Mail... This opens a modal new message window and locks out both Excel and Outlook. So the few cells of data I wanted to copy/paste into the email body, can't.

Is there anyway to prevent this? I don't want the new message windows to be modal.

share|improve this question
    
Still the case in Outlook 2013. So irritating. –  Chris Nevill Aug 5 at 9:03

2 Answers 2

I have made VBA procedure to generate Outlook message. The result is the same, but Outlook and Excel are not blocked when you want to send Active Workbook. You can put button on Quick Access Toolbar and call this procedure from automatically loaded module from XLSTART.

Sub SendActiveWorkbook()
    'Create Outlook Message and add Active Workbook file to it
    Dim temp_file_full_name As String
    Dim folder As String
    Dim base As String 'File name without extension
    Dim ext As String

    'Create temp copy of ActiveWorkbook
    With ActiveWorkbook
        folder = Environ$("temp") & "\"

        'Workbook name
        base = .Name

        'If workbook did not saved on disk, it does not have extension
        If InStr(base, ".") > 0 Then
            ext = Split(base, ".")(UBound(Split(base, ".")))
            base = left(base, Len(base) - Len(ext) - 1)
        Else
            Select Case .FileFormat
                Case xlExcel8: ext = "xls"
                Case xlOpenXMLWorkbook: ext = "xlsx"
                Case xlOpenXMLWorkbookMacroEnabled: ext = "xlsm"
                Case xlExcel12: ext = "xlsb"
                Case Else: ext = "xlsx"
            End Select
        End If

        temp_file_full_name = folder & base & "." & ext
        .SaveCopyAs temp_file_full_name
    End With

    'Create Outlook message with attachment of temp file and display it
    With CreateObject("Outlook.Application").CreateItem(0)
        .Subject = base
        .Attachments.Add temp_file_full_name
        .Display
    End With

    'Delete temp file. We don't need it anymore
    Kill temp_file_full_name
End Sub
share|improve this answer

Is there anyway to prevent this?

Have another instance of Outlook/Excel open. No other way to go about this

share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.