Take the 2-minute tour ×
Super User is a question and answer site for computer enthusiasts and power users. It's 100% free, no registration required.

Is there a way to get the same functionality as the unix command ln -s in the Mac OS X Finder (OS 10.5)? I want to be able to create symbolic links while working in Finder windows without opening the Terminal.

Note that the Make Alias command in Finder is not what I want because those aliases cannot be navigated in the Terminal (but links created with ln -s can be navigated by both the Terminal and Finder).

share|improve this question

8 Answers 8

up vote 13 down vote accepted

What about that creating symbolic links in the Finder via AppleScript ?

Here's the most relevant script in that link:

on run
    open {choose file with prompt "Choose a file to create a symbolic link:" without invisibles}
end run

on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Just paste it into AppleScript Editor and save it as an application. Then you can drag it over your finder's toolbar or link it on the dock.

share|improve this answer
2  
The 2nd comment at that link, left by jonn8n, gives exactly the functionality I was looking for. Although, I'm a bit surprised this is not possible within Finder itself. –  Michael Schneider Aug 18 '09 at 11:09
    
@cawas thank you for the edit! ;) –  nuc Mar 4 '11 at 9:59
    
you're welcome! ;) –  Cawas Mar 4 '11 at 11:51

SymbolicLinker will do exactly what you're looking for, and it's free.

alt text

share|improve this answer
1  
FWIW, SymbolicLinker still works in Mavericks 10.9.3. –  martineau Jun 28 at 16:03

An applescript at the link provided by user nuc answered my question. Here is the applescript reproduced in case that link disappears.

I preferred the script given by the commenter jonn8n, which was also reproduced as Macworld article.

on run
    open {choose file with prompt ¬
    	"Choose a file to create a symbolic link:" without invisibles}
end run
on open the_files
    repeat with i from 1 to (count the_files)
    	try
    		set posix_path to POSIX path of (item i of the_files)
    		if posix_path ends with "/" then set posix_path to ¬
    			text 1 thru -2 of posix_path
    		do shell script "ln -s " & quoted form of posix_path ¬
    			& " " & quoted form of (posix_path & ".sym")
    	end try
    end repeat
end open

I saved this as an application using Script Editor and dragged the application to the Finder sidebar so I can now create symbolic links by dragging files or folders onto the application icon.

share|improve this answer

Path Finder adds this to your Finder, and adds a lot more features.

share|improve this answer

A possible improvement on this script would be changing the run handler to use the currently selected files from the Finder, as so:

on run
    tell application "Finder" to set sel to selection
    open sel
end run
on open the_files
    repeat with i from 1 to (count the_files)
    	try
    		set posix_path to POSIX path of (item i of the_files as alias)
    		if posix_path ends with "/" then set posix_path to ¬
    			text 1 thru -2 of posix_path
    		try
    			do shell script "ln -s " & quoted form of posix_path ¬
    				& " " & quoted form of (posix_path & ".sym")
    		on error
    			try
    				do shell script "ln -s " & quoted form of posix_path ¬
    					& " " & quoted form of (posix_path & ".sym") with administrator privileges

    			end try
    		end try
    	end try
    end repeat
end open

You could also edit [application]/Contents/Info.plist to add

<key>LSUIElement</key>
<true/>

Just before the last </dict>. This would mean the app would run in the background, and wouldn't come to the front when you clicked on it.

share|improve this answer

Also, in Snow Leopard where SymbolicLinker doesn't work, you can create a Service with Automator to do either the Terminal command or AppleScript to create a symbolic link.

share|improve this answer
1  
Actually SymbolicLinker does work on Snow Leopard since, at least december 2009. –  Cawas Mar 3 '11 at 12:22

One more AS:

tell application "Finder"
    repeat with f in (get selection)
        set p to POSIX path of (f as text)
        set p2 to POSIX path of (desktop as text) & name of f
        do shell script "ln -s " & quoted form of p & " " & quoted form of p2
    end repeat
end tell
share|improve this answer

Try looking here : http://www.techiecorner.com/528/how-to-create-shortcut-in-mac-os-x/

This is built into OSX already if you press the control key when you click on something.

share|improve this answer
4  
Only it's not a symbolic link that's created. You can cd into a symbolic link to a folder, but not into a Finder alias. Read the question, it already states this. (Moderators: We might want to leave this non-answer in, to prevent further answers along this line) –  Daniel Beck Mar 8 '11 at 9:14
2  
@daniel I doubt it will help much preventing, as answers in this line typically come from non-reading-people. :P –  Cawas Mar 8 '11 at 17:45

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.