How can I make terminal VIM my default editor application in Mac OS X?

Question

I am aware of MacVim, and while it's very nice I am constantly in the terminal. Why have two programs running when I could stay in one?

So the question is, how can I make VIM (run in iTerm2) the default text editor?

Answer 1

See my answer here, but use a Run AppleScript action in Automator instead and use the following AppleScript code:

on run {input, parameters}
    if (count of input) > 0 then
        tell application "System Events"
            set runs to false
            try
                set p to application process "iTerm"
                set runs to true
            end try
        end tell
        tell application "iTerm"
            activate
            if (count of terminals) = 0 then
                set t to (make new terminal)
            else    
                set t to current terminal
            end if
            tell t
                tell (make new session at the end of sessions)
                    exec command ("vim \"" & POSIX path of first item of input as text) & "\""
                end tell
                if not runs then
                    terminate first session
                end if
            end tell
        end tell
    end if
end run

This'll open a new iTerm window if there's none, otherwise a new tab, and open the file in there. Result: