Can I use leaders (or equivalent) inside tables in Word 2007?

Question

I want to layout something like the following:

1. A question           ...............     ...............
2. Another question     ...............     ...............
3. A third question     ...............     ...............

In other words, I want a series of questions layed out as a table, with leader dots going from the beginning to the end of certain cells. I want to avoid manually inserting dots (using a solution like leader tabs instead) and I also want to avoid doing a lot measuring work that has to be repeated if the table changes, or if I add table variants with different numbers of columns. Is this possible using Microsoft Word 2007?

On a related note: I'm still deciding on a layout/word processing application to use after replacing my old one. Would this kind of thing be easier to accomplish with Adobe InDesign or any other application?

Answer 1

There is no way to do this with the Word GUI.

Here is a Macro that will automatically fill all blank cells in a document with a tab leader that fills the cell exactly.

Sub FillCellsWithTabLeader()
'
' Fill cells with tab leader Macro
'
'

For Each tbl In ActiveDocument.Tables
    FillCells (tbl)
Next tbl

End Sub

Function FillCells(tbl)

    For Each acell In tbl.Cells

        For Each ntbl In acell.Tables
            FillCells (ntbl)
        Next ntbl

        acell.Select
        Set rngtable = acell.Range
        rngtable.MoveEnd Unit:=wdCharacter, Count:=-1
        If rngtable.Text = "" Then

            Selection.ParagraphFormat.TabStops.Add Position:=acell.Width - (acell.LeftPadding + acell.RightPadding), _
                Alignment:=wdAlignTabLeft, leader:=wdTabLeaderDots
            Selection.TypeText Text:=vbTab
        End If
    Next acell
End Function

Layout your document, then make a master backup copy before applying this macro. Then if you need to make changes just use your master to create a new copy and run the macro again.

To use this macro code:

1. Choose File > Word Options
2. Check 'Show Developer tab in the ribbon'
3. Go to the Developer tab and click 'Macros'
4. Type the name 'FillCellsWithTabLeader'
5. Click 'Create'
6. Copy & Paste this code over the pre-generated code stub.
7. Close the VBA Window.
8. Click Macros, select FillCellsWithTabLeader and click Run to run the code.

Answer 2

To accomplish this, you can create a table with as three columns and as many rows as you would like. You can remove the borders so that it appears the way you would like by right clicking on the table, selecting Table Properties... and on the Table tab, select the button Borders and Shading... This will bring up a new dialog. On the Borders tab, choose the None setting.

For the '..........', you can manually input a string of '.' the length that you like and then you can apply the same string to all cells in columns B & C by multi selecting the columns and pasting.