How to really change programmatically ip address without reboot (with no connection too)?

Question

Really, I tried everything, and there is no solution that works for me.

1. WMI - everything perfect, but I can't change ip address when there is no connection. O_o Are you joking me? How can I make a connection without correct Ip-address?
2. IPHelper - not doing anything. Just adding address to the table. Not work after reboot.
3. netsh - the stupid way I think, but ok, if you don't no another ways you can try. Before you will know, that network adapters name can contain international characters. Did someone know how it works actually, I mean inside?
4. Registry - working after reboot. I don't want to reboot. May be someone know how to notify about reg entries changes?

Answer 1

I made a script you may like.
It uses netsh to achieve what you need.

Just copy the code here into a new file and name it something like configip.bat or whatever you prefer (just don't call it ipconfig :)

You will need to modify several things in the script:
IP addresses you want, subnet masks and gateways.
All DNS servers are set to Google's (8.8.8.8) so they are very likely to work for you - unless your ISP requires you use their ones. In that case, use those.

You have several options for local network (wire and wireless), as well as DHCP (autoassigned IP).
There is also an option to dump your current configuration so you can see how it looks from netsh perspective.
This will allow you to modify my script with ease as you will have all the parameters in c:\networkconfig.txt file.

Of course, should you need further help with modification, I'll be here :)

@echo off
cls
:start
echo.
echo IP Configuration
echo.
echo 1. LAN Home
echo 2. LAN Office
echo 3. LAN DHCP
echo 4. WLAN Home
echo 5. WLAN Office
echo 6. Configuration Dump
echo 7. Quit
echo.


set /p userinput=Enter your choice: 
set option=%userinput:~0,1%
if "%option%"=="1" goto homelan
if "%option%"=="2" goto officelan
if "%option%"=="3" goto landhcp
if "%option%"=="4" goto homewan
if "%option%"=="5" goto officewan
if "%option%"=="6" goto configdump
if "%option%"=="7" goto end
echo.
echo Invalid choice
goto start

:homelan
echo.
echo Applying LAN HOME configuration.
echo.
netsh interface ip set address "Local Area connection" static 192.168.1.2 255.255.255.0 192.168.1.1 1
netsh interface ip set dns name="Local Area Connection" static 8.8.8.8
goto end

:officelan
echo.
echo Applying LAN OFFICE configuration.
echo.
netsh interface ip set address "Local Area connection" static 123.456.78.90 255.255.255.0 123.456.78.254 1
netsh interface ip set dns name="Local Area Connection" static 8.8.8.8
goto end

:landhcp
echo.
echo Applying DYNAMIC configuration.
echo.
netsh interface ip set address name="Local Area Connection" source=dhcp
netsh interface ip set dns name="Local Area Connection" source=dhcp
goto end

:homewan
echo.
echo Applying WLAN HOME configuration.
echo.
netsh interface ip set address name="Wireless Network Connection" source=dhcp
netsh interface ip set dns name="Wireless Network Connection" source=dhcp
goto end

:officewan
echo.
echo Applying WLAN OFFICE configuration.
echo.
netsh interface ip set address name="Wireless Network Connection" static 123.456.78.90 255.255.255.0 123.456.78.254 1
netsh interface ip set dns name="Wireless Network Connection" static 8.8.8.8
goto end

:configdump
netsh -c interface dump > c:\networkconfig.txt
echo.
echo Config file "c:\networkconfig.txt" created.
echo.
echo To restore settings from config dump, use:
echo netsh -f networkconfig.txt
echo.
pause
goto end

:end