Trying to hide a folder and unhide it in the same batch file with the attrib command

Question

I am trying to hide a folder with a batch file, using the attrib command and I also want to unhide the file with the same batch file. can i do this as a single batch file? or do i have to call another and what commands do i use to make it possible. thanks

So far I have

attrib +h +s Foldername

and

attrib -h -s Foldername

But that isn't working because as soon as i unhide it, it hides again.

Answer 1

@echo off
Set /P Answer=Do you wish to hide File (Y/N)?
if /I {%ANSWER%}=={y} (goto :yes)
if /I {%ANSWER%}=={Y} (goto :yes)
if /I {%ANSWER%}=={n} (goto :no)
if /I {%ANSWER%}=={N} (goto :no)
:yes
attrib +h Foldername
pause
exit
:no
attrib -h Foldername
pause
exit

This batch file will make it that if you choose Y for yes, it will hide the file and if you choose N for no, it will unhide the file. Original batchfile.

Answer 2

I have tried this way:-

attrib +h +s tempFolder
pause
attrib -h -s tempFolder
pause

With this batch file, I can see the folder is hidding and unhidding accordingly.

Answer 3

Something like this should work:

Set _Path=C:\foldername
For /F "Delims=" %%I In ('Attrib "%_Path%"') Do Set _Attribs=%%I
If "%_Attribs:~4,1%"=="H" (
  Attrib -S -H "%_Path%"
  Attrib /D /S -S -H "%_Path%"\*.*
) Else (
  Attrib +S +H "%_Path%"
  Attrib /D /S +S +H "%_Path%"\*.*
)

Got this from the techguys.org

Answer 4

Based on this comment, I assume you wish to create a batch file that will toggle the hidden state depending on the current state.

Based on your example, I assume you want to set it to both hidden and system if it is not hidden nor system at the moment, and if either one is set then clear both.

@echo off

set _folder="Foldername"

dir /a:h %_folder%>nul 2>nul
if %errorlevel%==0 goto clear

dir /a:s %_folder%>nul 2>nul
if %errorlevel%==0 goto clear

attrib +h +s %_folder%

exit /b


:clear
attrib -h -s %_folder%

exit /b

Ok, I'll explain this step by step.

• @echo off prevents output from showing up

• Using the _folder variable makes it easier to change the name. You could also set it to %*, meaning all parameters passed to the batch file, which can then be used like so: batchfile.bat path_to_folder

• The dir command is used to determine if the folder is hidden, then if it is marked system. In each case, It searches for the folder with filtering so only those with the appropriate attribute set are found. If it can find the folder with that attribute filter, errorlevel is set to 0. Otherwise it is 1. >nul 2>nul prevents stdout and stderr output.

• If it can find that either the hidden or system attribute is set, it jumps (goto) the :clear label, where those attributes are unset.

• If it can't find those attributes set, it sets both of them.