setting ERRORLEVEL to 0

Question

I have a batch file that is a wrapper around an installer. This batch file checks the error level returned by the installer and prints accordingly.

I noticed that if I execute set ERRORLEVEL=0 in a command prompt right before kicking off the batch file (in the same command window/environment), the installer never messes with the errorlevel and my batch script always returns passed. I would assume %ERRORLEVEL% is a variable defined by Windows and is used specifically to print out errors from programs and scripts and that using the variable in a batch file or something else would be 'at your own risk' because it could be changed at any moment by another process.

From what it seems like, when I set errorlevel in the given environment, it then somehow terminates the use of errorlevel as a holder of the exit code. Does anyone know why this is? To me its just weird unexpected behavior. Any information on the subject would be greatly appreciated!

Answer 1

You are redefining the system variable into a regular one. When you do this, the system will not use it until the command session is closed.

The best way would be to use

exit /b 0

in another batch file and call it from your primary script. Where the number 0 is your wanted errorlevel. Either that or use a command that resets the errorlevel for you, such as echo, findstr etc.

For example the following commands would all set ERRORLEVEL to 0 within your batch-file:

VERIFY > nul

cmd /c "exit /b 0"

ver > nul     

Answer 2

You should never assign your own value to dynamic system variables like ERRORLEVEL, PATH, CD, DATE, TIME, etc. Doing so will prevent code from seeing the dynamic value. You can restore the dynamic value by simply undefining the user defined value. For example:

set "errorlevel="

If you want to force the errorlevel to 0, then you can use this totally non-intuitive, but very effective syntax: (call ). The space after call is critical. If you want to set the errorlevel to 1, you can use (call). It is critical that there not be any space after call.

(call)
echo %errorlevel%
(call )
echo %errorlevel%

A more intuitive, but less convenient method to set the errorlevel is to use a dedicated subroutine in a batch file:

call :setErr 1
echo %errorlevel%
call :setErr 0
echo %errorlevel%
exit /b

:setErr
exit /b %1

Or if on the command line, you could use

cmd /c exit 1
echo %errorlevel%
cmd /c exit 0
echo %errorlevel%

Answer 3

I personally use this:

cd .

Works even in unix shell.

Answer 4

This is the only thing I have found that works.

call (exit /b 0)

Needed it in a script which uses 3rd party script that detects ERRORLEVEL, but is not resetting error level its self properly.

Answer 5

Here are some other ways to reset the ErrorLevel state, which even work in MS-DOS (at least for version 6.22):

more < nul > nul

rem // The `> nul` part can be omitted in Windows but is needed in MS-DOS to avoid a line-break to be returned:
sort < nul > nul

---

The following methods work in MS-DOS only:

command /? > nul

fc nul nul > nul

---

For the sake of completeness, this sets the ErrorLevel state to 1, valid for both Windows and MS-DOS:

< nul find ""

Answer 6

These will also work: (Sets errorlevel to 1)

Method 1

color 00

Method 2

echo A | find "B"

You can also use this to set errorlevel 1-26:

echo Your errorlevel<sup>th</sup> character between A-Z | choice /c:Enter A-Z here /n

Answer 7

User aschipfl gave best answer, to complete it, using smallest function FIND:

This line will set ERRORLEVEL to 1, in DOS or later:

<nul find ""
if errorlevel 1 echo ERRORLEVEL is 1 or more

This line will set ERRORLEVEL to 0, in DOS or later:

echo a |find "a" >nul
if errorlevel==0 echo No Error

Answer 8

For Windows 10 and 11:
In my experience (call ) works reliably, ‘except’ for a pitfall inside round brackets (…).

Inside round brackets:
● Resetting with (call ), as well as calling sub exit /b 0 etc., still works.
but:
● %ERRORLEVEL% returns the state from outside the brackets!
● !ERRORLEVEL! returns the correct state.

---

Example code

@echo off
SETLOCAL EnableDelayedExpansion
echo Outside brackets:
echo   Forcing an error.
dir "totally non existing whatsoever" > nul 2>&1
echo     ^%%ERRORLEVEL^%% = %ERRORLEVEL%
echo     ^^!ERRORLEVEL^^! = !ERRORLEVEL!
if 0 EQU 0 (
  echo Inside brackets:
  echo   Clearing the error.
  (call )
  echo     ^%%ERRORLEVEL^%% = %ERRORLEVEL%
  echo     ^^!ERRORLEVEL^^! = !ERRORLEVEL!
  echo   =^> ^%% enclosed variables will not update before leaving the brackets!
)
ENDLOCAL

Output:

Outside brackets:
  Forcing an error.
    %ERRORLEVEL% = 1
    !ERRORLEVEL! = 1
Inside brackets:
  Clearing the error.
    %ERRORLEVEL% = 1
    !ERRORLEVEL! = 0
  => % enclosed variables will not update before leaving the brackets

---

Details & related:
Using !ERRORLEVEL! requires SetLocal EnableDelayedExpansion.
Wrong errorlevel inside parenthesis in Windows batch script
https://stackoverflow.com/questions/31173772/command-script-exit-code-not-seen-by-same-line-or