Take the 2-minute tour ×
Super User is a question and answer site for computer enthusiasts and power users. It's 100% free, no registration required.

Much like Ask Toolbar is bundled with Java (and other applications), I've encountered several instances of applications bundling, and luring the user into installing, McAfee Security Scan. Adobe, I'm looking in your direction!

I'll try my best not to install McAfee Security Scan when prompted, or use Ninite (which doesn't install bundled software) when installing applications, but when providing support for my family and friends, it's obvious they don't.

How can I prevent McAfee Security Scan from being installed, e.g. bundled with other applications, in the first place?

share|improve this question

1 Answer 1

Using the same principle, as I originally used for preventing Ask Toolbar to be installed by Java, I've created a script that removes McAfee Security Scan, creates the folder MSS installs into and modify the permissions, so no one can write to it.

Copy the following code to Notepad, save it as a .cmd file and run it in an elevated command prompt:

REM Silently uninstall McAfee Security Scan (tested with 3.8)
REM and prevent future installations

REM Detect processor architecture
set proc_arch=x64
if "%PROCESSOR_ARCHITECTURE%" == "x86" ( 
    if not defined PROCESSOR_ARCHITEW6432 set proc_arch=x86
) 

REM Define McAfee Security Scan path
if "%proc_arch%" == "x86" set McAfeePath=%ProgramFiles%\McAfee Security Scan
if "%proc_arch%" == "x64" set McAfeePath=%ProgramFiles(x86)%\McAfee Security Scan
set McAfeeReadme=%McAfeePath%\..\McAfee_ReadMe.txt
set McAfeeRevert=%McAfeePath%\..\McAfee_RestorePermissions.cmd

REM Uninstall McAfee Security Scan
if exist "%McAfeePath%\uninstall.exe" start "" /wait "%McAfeePath%\uninstall.exe" /s /inner

REM Create dummy McAfee Security Scan folder
md "%McAfeePath%"

REM Add explanatory text file, as to why the dummy folder is there
echo The 'McAfee Security Scan' folder is has been created and write protected,> "%McAfeeReadme%"
echo in order to prevent McAfee Security Scan from being 'accidentally'>> "%McAfeeReadme%"
echo installed, e.g. by Adobe Reader.>> "%McAfeePath%\readme.txt">> "%McAfeeReadme%"
echo.>> "%McAfeeReadme%"
echo This has been done using ICACLS by denying write access to the>> "%McAfeeReadme%"
echo EVERYONE security group.>> "%McAfeeReadme%"
echo.>> "%McAfeeReadme%"
echo To revert permissions run:>> "%McAfeeReadme%"
echo %McAfeeRevert%>> "%McAfeeReadme%"

REM Create script to remove restrictions
echo icacls "%McAfeePath%" /remove:d *S-1-1-0> "%McAfeeRevert%"

REM Deny everyone (SID: S-1-1-0) write access
icacls "%McAfeePath%" /deny *S-1-1-0:(OI)(CI)W

Please note: ICACLS is included in Windows Vista and later. You can download ICACLS for Windows XP/Server 2003 through Microsoft KB943043 (but must first be requested, after which you will receive a link by e-mail to download it).

A similar approach can most likely be used to block most other kinds of piggybacking crapware.

Windows Explorer quirk: Access denied

Windows Explorer behaves a little strange if you try to open the folder. Even though you still have read access to the folder, Windows Explorer will tell you that access is denied, even though only write access has been denied.

This doesn't happen if you simply only have been assigned read access in the first place, but it seems to happen when you have been assigned read/write permission to the folder and then been denied write access.

Reverting permissions

The script has been updated to add a 'read me' text file and a script for removing the restriction again. Both are stored in the 32-bit program files folder.

share|improve this answer
1  
It's ridiculous that you have to go to such efforts to remove unwanted software. All I can add is: be vigilant when installing software. God bless open source, and Adobe can go to hell. –  user184411 Dec 25 '13 at 22:17

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.