Take the 2-minute tour ×
Super User is a question and answer site for computer enthusiasts and power users. It's 100% free, no registration required.

I am wondering whether it is possible to automatically open a batch file as admin when you double-click on the batch file, because the commands need to be run with administrative rights.

Note: I already know about the solution of right-clicking on the file and clicking on Run As Administrator, but this is not an automatic solution.

share|improve this question
1  
    
I was able to get this to work for me: stackoverflow.com/a/13811519/27928 –  Rohit Oct 17 '14 at 18:26

7 Answers 7

up vote 16 down vote accepted

Yes, you're able to run a batch file with administrative rights. Unfortunately, you can't do this directly from the batch file it self. You would need to first create a shortcut of that batch file and change the properties for that shortcut in order to make this work.

To create a shortcut, there are many ways but the simplest and the fastest way is by using the Send to option in the context menu.

Right click batch file > Send to > Desktop (create shortcut)

Of course you can send the shortcut to where ever you would like. To elevate the batch file to run as admin, follow the steps below:

  1. Right-click the shortcut you just created (should be on the desktop or where ever you send it)
  2. Under the Shortcut tab, click the Advanced... button.
  3. Check the Run as administrator checkbox and press OK to both the modal window and the main properties window.
  4. Run the shortcut by double-clicking it and the batch file should run as administrator.
share|improve this answer
    
Thanks this really helped alot! –  Antp Jul 28 '14 at 4:50
1  
You could always force the batch file to call the shortcut, and have the shortcut pass a parameter to know not to call the short cut. You would insert something like if "%~1" == "" start %USERPROFILE%\Desktop\Shortcut.lnk && GOTO :EOF right below @echo off, and make the shortcut link to program.bat a instead of just program.bat. –  trlkly Jul 28 '14 at 5:20
1  
Ifedi writes "The accepted answer[this one from Tech1337] does indeed work. But I found that in Windows 7, I had to endure the UAC dialog each time the shortcut is clicked." <-- Though somebody else says it works without UAC –  barlop May 31 at 15:08

As posted in an answer by Ben Gripka to another question:

REM --add the following to the top of your bat file--


@echo off

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params = %*:"=""
    echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------
share|improve this answer
    
Yes i found this and am using it currnetly. Thanks anyways! –  Antp Dec 18 '14 at 4:20
    
best answer IMO. –  Jus12 Jul 11 at 18:30

The accepted answer does indeed work. But I found that in Windows 7, I had to endure the UAC dialog each time the shortcut is clicked. This IMHO detracts significantly from the "automatically" in this question!

Then I found that in my own situation, the .bat file in question is to be run by Task Scheduler. In this case, checking the Run with highest privileges option on the General tab of the task, nicely takes care of the problem. The .bat is then run as administrator without any hassles.

PS: I didn't realize I couldn't upload images on this answer, 'cause I have a nice little screenshot sitting right with me now! Or can I?

share|improve this answer
2  
If you add links to the images somebody will inline them for you. –  Ramhound Oct 7 '14 at 18:50
    
@Ramhound. Add links to the images? The image is on my desktop, not somewhere online. Or, surely I'm missing something? –  Ifedi Okonkwo Oct 8 '14 at 18:10
    
Yes; You upload them; You just can't inline the screenshots into your answer. –  Ramhound Oct 8 '14 at 18:19
    
Either that upload button wasn't there, or I was half-blind yesterday! I'm sure it was the latter. Anyhow, I completed the file upload very nicely, only to be told I needed a rep of 10 to post images. Thanks, though. –  Ifedi Okonkwo Oct 8 '14 at 18:27
    
You can still place the link in the answer though. –  Ramhound Oct 8 '14 at 18:29

on Windows 7

  1. Create a shortcut to that Batch file

  2. Right-click the shortcut file

  3. Click advance button to find a checkbox for running as administrator

Check the screenshot below

Screenshot

share|improve this answer
    
Your saying the same as the accepted answer. –  Antp Feb 11 at 9:53
    
Yes, I just wanted to create a simple list with screenshot for everyone that is in hurry. –  fedmich Feb 11 at 14:00
    
If someone's in a hurry I doubt that they will scroll to the bottom for the answer.thanks anyway –  Antp Feb 11 at 21:14
    
@antp I just did, I wanted a simple working answer :) must go, bye :) –  jave.web Jun 9 at 16:34
    
What ever floats your boat. –  Antp Jun 9 at 21:50

Alternatively you could create a second batch file, this could allow you to run anything as an administrator, while only entering the administrator password once. The password is saved in an authentication token, and takes some real computer know how to crack.

runas /savecred /user:(domain)\(admin user) "(file path to exe,bat,whatever)"
share|improve this answer

You can run batch files as admin by right clicking on the file and clicking on Run As Administrator

Alternatively, you could also do Shift+Right Click then click on Run as Different User if you need to run it as a user with administrative privileges.

share|improve this answer
3  
Sorry this is useless because i want it to run as admin automatically. –  Antp Jul 28 '14 at 4:52
    
Right. Misread the question. –  Lawrence Jul 28 '14 at 4:53

You can use my script Batch_Admin to automatically elevate the Administrator for use in any type of Batch own script, or BAT or .CMD. This function ensures the work on a standard environment, with standard tools and in the same way in different Windows systems. It uses several standard and built-in Windows commands. Do not use any other external scripts. It can be used to call any program as Administrator, not just scripts Batch. It suffices to create a small script, which then call the program that requires permission Administartor. Place this in any search PATH folder (from %PATH%).

To use it, you simply insert the following line (exactly as) in its parent Batch script, which is to be run as Administrator. This is best done at the top of our parent script and it is best that first, which will be called via the CALL further, some sub-scripts (see detailed explanation below).

net session >nul 2>nul&if errorlevel 1  Batch_Admin "%~0" %*

This can be inserted inside any child scripts, called by CALL syntax. To display a message while it is still does not have Administrator privileges, eg. for 5 seconds before calling Batch_Admin set the variable "ShowAdminInfo" on the number of seconds

SET ShowAdminInfo=5
net session >nul 2>nul&if errorlevel 1  Batch_Admin "%~0" %*

So how it works:

• Calls UAC.ShellExecute through VBScript to pick up user permissions

• Batch runs the script, or BAT or CMD

• Script caller can have a long name spaces included in the call in quotes

• Give back all the parameters call the master script passed from the command line, as if there was no transmission of the call and start something from scratch, also with special characters, like exclamation marks (!) and percentage (%), and also with parentheses ()

• Holds a master script location if the call took place in the directory where this script is the master

• Auxiliary displays a message if we set before ourselves the variable "ShowAdminInfo", eg. for 5 seconds which can prevent the immediate passage of the rights of the Administrator giving additional information and the possibility of an informed decision. Examples of setting that must be set: SET ShowAdminInfo=5 By default, because this variable is not defined, it does not display.

• The script is calling also in the system search path % PATH% and from network resource, such as: \Computer\share\test.bat

• Prevents misunderstandings in writing the necessary auxiliary files when the script calls several Batch_Admin almost at the same time. It uses the random number from 1 to 100

• But, the best is to use it on parent script. The transition to Administrator rights always requires that you run the script completely again, in a new window, in a new environment, without recourse to the the variables are set previously in our script and values of these variables did not pass then to call as Administrator. Just the script will be executed again.

Below a complete script Batch_Admin. Extended information about this is on my site.

Copy the following text into Notepad and save it to disk as: Batch_Admin.bat

@echo off
if "%~1"=="" (echo *** Batch_Admin ***&echo.&echo Automatically get admin rights for another Batch. See info inside.&TIMEOUT /T 30>nul&goto:eof)

::  A D M I N I S T R A T O R   - Automatically get admin rights for script batch. Paste this on top:    net session >nul 2>nul&if errorlevel 1  Batch_Admin "%~0" %*
::                                Also keep Batch directory localisation and then set variable:   PATH_BAT
::                                if earlier variable "ShowAdminInfo" is empty (not defined) then no info, else showing info with number of seconds
::
::                                Elaboration:  Artur Zgadzaj
setlocal
setlocal DisableDelayedExpansion

SET "Localy="
if exist "%~1"      SET "Localy=YES"
if exist "%~1.BAT"  SET "Localy=YES"
if exist "%~1.CMD"  SET "Localy=YES"
if defined Localy   FOR %%I IN ("%~1") DO SET "PATH_BAT=%%~dI%%~pI"

 SET P1=%~1
 SET Parameters=%*
 SET Parameters=%Parameters:!=^^!%
setlocal EnableDelayedExpansion
 SET Parameters=!Parameters:%P1%=!
 SET Parameters=!Parameters:%%=%%%%!
setlocal DisableDelayedExpansion
 SET Parameters=%Parameters:~3%

net session >nul 2>nul&if not errorlevel 1  goto Administrator_OK

if not defined ShowAdminInfo   goto skip_message_Administrator
echo.
echo Script:  %~1
echo.
echo *****************************************************************
echo ***    R U N N I N G     A S     A D M I N I S T R A T O R    ***
echo *****************************************************************
echo.
echo Call up just as the Administrator. You can make a shortcut to the script and set:
echo.
echo          shortcut ^> Advanced ^> Running as Administrator
echo.
echo     Alternatively run once "As Administrator"
echo     or in the Schedule tasks with highest privileges
echo.
echo Cancel Ctrl-C or wait for launch  %ShowAdminInfo%  seconds ...
TIMEOUT /T %ShowAdminInfo% > nul

:skip_message_Administrator
MD %TEMP% 2> nul
SET /A $Admin$=%RANDOM% * 100 / 32768 + 1

SET "Percent="
del "%TEMP%\$Admin_%$Admin$%_Test.bat" 2>nul
echo %Parameters% > "%TEMP%\$Admin_%$Admin$%_Test.bat"
if not exist "%TEMP%\$Admin_%$Admin$%_Test.bat"  SET Percent=^"
del "%TEMP%\$Admin_%$Admin$%_Test.bat" 2>nul

echo @SET "PATH_BAT=%PATH_BAT%"               > "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"
echo @SET "BatchFullName=%BatchFullName%"    >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"
if defined Localy  (echo @CD /D "%PATH_BAT%" >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat")
echo @"%~1" %Parameters% %Percent% >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"

echo SET UAC = CreateObject^("Shell.Application"^)                                   > "%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
echo UAC.ShellExecute "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat", "", "", "runas", 1 >> "%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
"%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
endlocal
exit /B

:Administrator_OK
"%~1" %Parameters%
goto:eof
REM *** A D M I N I S T R A T O R  - Automatically get admin rights  (The End)  ***
share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.