Using 'send to...' upload file to FTP and copy it's URL to clipboard

Question

I hate odd, almost useless apps on my PC. I don't want them to hang in there running and waiting for me use it once in a week. So I thought the instant fileshare could be done using almost only Windows tools.

I found how to send file to FTP using command line so the rest of the trick should be to copy a filename and add the FTP URL before it. Sounds like easy task but I can't see any option to copy a filename using batch file or whatever

The easiest and clean way to achieve that I found is to make an AutoIT script, compile it to exe with send to ftp command line options. I think I could google all of the code to do that. Any suggestions?

Answer 1

Create a batch file that runs ftp.exe and takes a file path as an argument.

(I assume that ftp.exe is what you use to "send file to FTP using command line".)

Example:

@echo off
set FILE=%1
set SCRIPT=%TEMP%\ftp.txt

echo open example.com > %SCRIPT%
echo username>> %SCRIPT%
echo password>> %SCRIPT%
echo cd /path >> %SCRIPT%
echo put %FILE% >> %SCRIPT%
echo bye >> %SCRIPT%

ftp.exe -i -s:%SCRIPT%

Create a shortcut to the batch file in %APPDATA%\Microsoft\Windows\SendTo (i.e. typically in C:\Users\username\AppData\Roaming\Microsoft\Windows\SendTo).

Now the shortcut will appear in Send to submenu in Windows Explorer's file context menu. If you click it, the Windows Explorer runs the batch file, automatically passing path to a selected file to the script as a command-line argument.

Note that the script as is won't work when multiple file are selected. But it's not difficult to improve it to support multiple files.

---

To insert an URL of the file to a clipboard, use %~nx1 to extract filename only, use it to assemble the URL and pass the result to clip.exe:

echo ftp://localhost/%~nx1| clip

(just put this line to the end of the batch file)

Answer 2

So here is the answer. I used Cyrillic characters «Ъ» to point the ЪexactЪ things that should to be changed with your FTP info, no spaces after unsername nor password

@echo off
set FILE=%1
set SCRIPT=%TEMP%\ftp.txt
echo ЪYourFTPserverHEREwithShareFolderЪ~nx1| clip
echo open ЪYourFTPserverHEREЪ > %SCRIPT%
echo ЪYourUsernameHereЪ>> %SCRIPT%
echo ЪYourPasswordHereЪ>> %SCRIPT%
echo cd ЪYourShareFolderHereЪ >> %SCRIPT%
echo type binary >> %SCRIPT%
echo put %FILE% >> %SCRIPT%
echo bye >> %SCRIPT%
echo ЪYourFTPserverHEREwithShareFolderForAsakeOfBigFilesЪ~nx1| clip
ftp.exe -i -s:%SCRIPT%

Create a shortcut to the batch file or the exact .BAT in %APPDATA%\Microsoft\Windows\SendTo (i.e. typically in C:\Users\username\AppData\Roaming\Microsoft\Windows\SendTo).

That batch say bye to tons of sharing websites about advertisements, just search for free ftp server and you can share on a snap