awk + print all line content except $1

Question

I write the follwoing awk script:

% echo /var/sysconfig/network/my_functions  alpha beta gama  | \
      awk -v word=alpha '$2  == word { print $0 }'

how to tell awk that I want to print all line except $1 (/var/sysconfig/network/my_functions PATH ) so I will get the following:

alpha beta gama

instead of

/var/sysconfig/network/my_functions alpha beta gama

remark: line content can be anything and not limit by strings/word quantity

Answer 1

I think in awk there's no way but to remove the first field manually. (There are other ways if you're willing to normalize the inter-field space.)

awk '$2 == word {match($0, "("FS")+"); print substr($0, RSTART+RLENGTH);}'

Answer 2

If you set $1 to "" you will leave the delimiting space. If you don't want to do that you have to iterate over the fields:

awk '{for (f=2; f<=NF; ++f) { if (f!=2) {printf("%s",OFS);} printf("%s",$f)}; printf "\n" }'

Edit: fixed per Gilles' comment.

Another way to do the same thing:

awk '{d = ""; for (f=2; f<=NF; ++f) {printf("%s%s", d, $f); d = OFS}; printf("\n") }'

Answer 3

Somehow I think this would be so much easier and more intuitive to do with the cut command:

echo /var/sysconfig/network/my_functions  alpha beta gama | cut -d' ' -f 2-

The only problem is that cut doesn't support multiple different types of whitespace at once for delimiters. So if you have spaces or tabs, it won't work.

Answer 4

 % echo /var/sysconfig/network/my_functions  alpha beta gama | \
      awk -v word=alpha \
             '$2 == word { $1=""; print $0 }'

Answer 5

This (somewhat complicated) solution, which is somewhat similar to Gilles’s answer,

• outputs no space at the beginning of the line,
• correctly handles the case where the input line begins with whitespace, and
• preserves inter-field whitespace.

awk -v word=alpha '
    $2 == word {
        i = index($0, $1)               # Find $1 within $0 (the line).
        if (i > 0) {                    # Sanity check; should always be true.
                i = i + length($1)      # Find space after $1.
                temp = substr($0, i)
                i = index(temp, $2)     # Find $2 in remainder of line.
                if (i > 0) {            # Sanity check; should always be true.
                        print substr(temp, i)
                }
        }
    }'

I believe the in-line comments explain it fairly well.  We find $1’s position in the line (remember, I’m explicitly not assuming that it’s at the beginning).  Then, à la Gilles’s answer, we strip $1 (and the whitespace before it, if any) off the line.  Then find $2’s position in the remainder of the line, and strip off the whitespace before that.

---

Here is a slight streamlining of Dennis Williamson’s answer.

awk -v word=alpha '$2==word { for (f=2; f<=NF; ++f) printf("%s%s", $f, (f==NF?ORS:OFS)) }'

Like Dennis’s answer, it outputs the fields $2, $3, …, $NF (omitting $1) with default separation.  Dennis took the approaching of preceding $3, …, $NF (but not $2) with the default output field separator.  I took the approach of following $2, $3, …, $(NF-1) (but not $NF) with the OFS.  And, since $NF is followed by the output record separator (ORS), we can use a ?: operator with no null terms, and eliminate the final printf("\n").

Answer 6

echo alpha beta gama | awk '{$1="";print}'

beta gama

Answer 7

Everyone always makes it harder than it is

$ echo /var/sysconfig/network/my_functions alpha beta gama |
awk -v word=alpha '$2==word{print substr($0,index($0,$2))}'
alpha beta gama

Answer 8

Use this if you want to change the delimiter. My delimiter is "|":

awk -F '|' '{d = ""; for (f=2; f<=NF; ++f) {printf("%s%s", d, $f); d = OFS}; printf("\n") }'