13

I have a big problem with the Portuguese version of MS Office 2007 and 2010.

The standard shortcuts that any common application uses are changed.
Some shortcuts that are not working: Ctrl+s (save), Ctrl+f (find) and Ctrl+a (select all).

I want to configure it to use the shortcuts of the English version.

There is an option that allow to configure each shortcut separately. Furthermore, I have to configure for each app, if I configure in Word, I will have to configure again for Excel.

How to use the shortcuts of the English version of MS Office regardless of the Office language?

Thanks

3
  • Same here!! Same language also. LOL. I'm thinking in installing the EN version and then add the Language pack for dictionary. Have you tried it?
    – Pedro77
    Jun 8, 2014 at 14:42
  • possible duplicate of How to change office shortcuts?
    – Pedro77
    Jun 10, 2014 at 11:52
  • In the italian version to save we need to presst ctrl+B, this is so annoying...
    – Luca
    Mar 19, 2015 at 9:34

3 Answers 3

3

I'm almost certain that there's not built-in way to change shortcuts in MS Office applications.

However, you can use AutoHotkey for this purpose.

The script

^a::
^f::
^s::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a")
           SendPlay, ^e
       if(A_ThisHotKey = "^f")
           SendPlay, ^b
       if(A_ThisHotKey = "^s")
           SendPlay, ^g
    }
    else
        SendPlay, %A_ThisHotKey%
return

How it works

  • ^a::, specifies one of the hotkeys that run the script before the return statement, where ^ indicates the Ctrl key.

  • WinGet, Process, ProcessName, A stores the active (A) window's process name in the variable Process.

  • if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$")) {...} else ... checks if Process matches the regular expression, i.e., if it matches one of the strings WINWORD.EXE or EXCEL.EXE.

    • If so, the first block gets executed.

      • if(A_ThisHotKey = "^a") checks if the pressed hotkey is Ctrl + A.

        If it is, it simulates the key bombination Ctrl + E, which is the Portuguese hotkey to select all1.

    • Otherwise, SendPlay, %A_ThisHotKey% simulates the key combination that was initially pressed.

      This way, other applications still behave as they should.

How to use

  1. Download and install the latest version of AutoHotkey.

  2. Save the above script as ms-office.ahk, using your favorite text editor.

  3. Double-click the file to run the script.

  4. If you wish, copy the script (or a link to it) in the Startup folder.

  5. To add further MS Office applications, just modify the regular expression.

    To add PowerPoint, e.g., replace (WINWORD|EXCEL) by (WINWORD|EXCEL|POWERPNT).

  6. To add further hotkeys, you have to modify two parts of the script.

    To add Ctrl + O (Open...), e.g., add the line ^o:: to the list at the very top add these lines inside the if block:

    if(A_ThisHotKey = "^o")
        SendPlay, ^a
    

1 At least, I think it is. I took the hotkeys from my Spanish MS Office. Adjust if needed.

1

Based on the previous answer, a couple more shortcuts (could be added to the previous answer):

^a::
^f::
^s::
^w::
^n::
^u::
^d::
^r::
^b::
^i::
^k::
^g::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a") ;seleccionar rango
           SendPlay, ^e
       if(A_ThisHotKey = "^f") ;buscar
           SendPlay, ^b
       if(A_ThisHotKey = "^s") ;guardar
           SendPlay, ^g
       if(A_ThisHotKey = "^w") ;cerrar
           SendPlay, ^r
       if(A_ThisHotKey = "^n") ;nuevo libro
           SendPlay, ^u
       if(A_ThisHotKey = "^u") ;subrayar
           SendPlay, ^s
       if(A_ThisHotKey = "^b") ;negrita
           SendPlay, ^n
       if(A_ThisHotKey = "^i") ;cursiva
           SendPlay, ^k
       if(A_ThisHotKey = "^d") ;filldown
           SendPlay, ^j
       if(A_ThisHotKey = "^r") ;fill right
           SendPlay, ^d
       if(A_ThisHotKey = "^k") ;hyperlink
           SendPlay, ^!k
       if(A_ThisHotKey = "^g") ;goto
           SendPlay, ^i
    }
    else
        SendPlay, %A_ThisHotKey%
return
0

The question is already 8 years old. Since then, there is a simpler alternative, as Microsoft released its Office's language packs for free.

Note: although this is a simple and clean approach, it has the side effect of also changing Office's interface (menus and dialog boxes) to English.

You can download the language packs for Office 2016, Office 2013 and Office 2010 in this link. Download and install the language pack for English, then execute the steps described in the download page to configure MS Office's display language. After a restart, the English shortcuts should be in effect.

Obs.: Initially I had some bugs after the language pack installation. That's because I installed a 64-bit language pack over my 32-bit Office. After correcting the problem, my MS Office is working as expected.

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .