How can I make windows command prompt return a substring from a command ouput

Question

My path is pointed towards a cloud folder (located at various places on my various devices) wherein I have stored a batch file that is supposed to locate itself on the machine, and then make that directory the new working directory of that session.

Locating the file

@echo off No clutter

cls clean slate

Echo Searching Because sometimes it takes a while

dir /b /s myScripts.bat And this outputs the full directory, including the file name.

So my first problem is getting rid of the file name. This is what I've tried:

set stringOne=dir /b /s myScripts.bat

%stringOne:~0, 60%

I found a script for counting the length of a string which I'll use to automatically deduce those values later if it turns out I actually need them.

Problem is I've found that if I lower that number to 10, the dir command is shortened like so:

dir c:\users\myUsername\cloudDrive\scripts, or whatever the case may be, and instead cmd inputs dir c:\users\m and searches ALL of that recursively.

Again, what I'd like to do is have it show me a modified version of the directory it searched, NOT modify the directory search command. I'll later use the final string produced to set my working directory to, but I'm trying to take this one step at a time so I understand what is happening.

EDIT: The ultimate goal of the SCRIPT is different from my purpose for writing it. When all is said and done I should be able to type myScripts.bat into cmd, on any computer which I have appended to it's PATH my cloud folder, and it will procure the directory of that cloud folder via means of the dir command, and then change it's working directory to that of the batch file.

Answer 1

To answer this part:

And this outputs the full directory, including the file name. So my first problem is getting rid of the file name.

In a batch file you can do

@echo off

:: locate 'myScripts.bat' and save its directory to 'myDir'
:: in case of multiple matches 'myDir' will be set to the last one
set "myDir="
for /f "delims=" %%x in ('dir /b /s myScripts.bat') do set "myDir=%%~dpx"
if not defined myDir echo not found ?? & exit /b 1

:: ready to use
echo myDir = "%myDir%"

To get a better hang of batch files, I recommend that you read the builtin help, starting with set /?, if /?, for /?, call /?.

[ EDIT ] Added "delims=" to handle paths with spaces correctly.

Answer 2

Lets say, you create a batch file called test.cmd, and you place the following text in it, the output will be as follows:

@echo off
echo %0
echo %cd%

set currentpath=%0

::remove any " if present
set currentpath=%currentpath:"=%

:: remove last 9 characters
set currentpath=%currentpath:~0,-9%

:: add quotes back
set currentpath="%currentpath%"

echo %currentpath%

pause

and the output will be if:

                C:\Windows\System32>%appdata%\..\..\desktop\test.cmd
%0:             C:\Users\LPChip\AppData\Roaming\..\..\desktop\test.cmd
%cd%:           C:\Windows\System32
%currentpath%:  "C:\Users\LPChip\AppData\Roaming\..\..\desktop"
                Press any key to continue . . .

The first command uses a replace function. The ~ operator means, substring replacement, by adding 0, the new string starts at position 0, the -9 means, to 9 positions from the right.

Of course the quickest and easiest way is still using %cd% to get the current directory, but as you want to find the current path of where the batchfile itself resides, the other method does just that.

A great resource for learning more about string manipulation is this site: dostips.com