Batch file to run programs as admin - error 740

Question

I am working on a small batch script that elevates basic windows programs to run as administrator.

All of the functions work fine but I have ran into a problem when trying to run "regedit.exe".

When option 3 is selected in the script and it should run regedit as admin I get error:

740: The requested operation requires elevation.

Here is the script:

echo off
cls
echo.
echo Start as admin:
echo /----------------\
echo # 1. CMD         #
echo # 2. Task Manager#
echo # 3. Regedit     #
echo # 0. Exit        #
echo \----------------/
echo.

set /p run=

if %run%==1 (
set run="cmd"
)

if %run%==2 (
set run="taskmgr"
)

if %run%==3 (
set run="regedit"
)

if %run%==0 (
exit
)

runas /savecred /user:admin %run%

Is there a workaround for this?

I would like make this working without installing third party programs, modifying the registry or disabling UAC.

Answer 1

You can pull it off by launching a new CMD prompt with RunAs, which you tell to launch your command.

To do this in your batch, change the last line to:

runas /savecred /user:admin "cmd /c %run%"

Answer 2

Add this to the top of your Batch file and at the end just put %run% instead of (runas /savecred /user:admin %run%)


@echo off

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params = %*:"=""
    echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

Answer 3

Perhaps this can help, or maybe starting the entire batch as admin may help, done by creating another batch script containing:

runas /user:admin C:\Path_to_your_batch_file\name.bat

Answer 4

1. Right-Click C:\Windows\regedit.exe and choose Properties
2. In the Compatibility-Tab choose "Run this program as an administrator"