Use modulo operation

To get the integer division result use `QUOTIENT`

. For example

```
=QUOTIENT(10000, 48)
```

To get the remainder use `MOD`

. For example

```
=MOD(10000, 48)
```

To divide by multiple units you need to get the new divisor after each step. The easiest way is creating separate columns for each different thing, then just hide the columns you don't need

```
╔═╦═══════════╤══════════╤════════╤════════════════════╤════════════╤═════════════════╤════════════╗
║ ║ A │ B │ C │ D │ E │ F │ G ║
╠═╬═══════════╪══════════╪════════╪════════════════════╪════════════╪═════════════════╪════════════╣
║1║total units│ cases │ units │ full pallets │ units │ full cases │ units ║
║ ║ │per pallet│per case│ │ remaining │ │ remaining ║
╟─╫───────────┼──────────┼────────┼────────────────────┼────────────┼─────────────────┼────────────╢
║2║ 10000 │ 36 │ 48 │=QUOTIENT(A2, B2*C2)│=A2-D2*C2*B2│=QUOTIENT(E2, C2)│=MOD(E2, C2)║
╟─╫───────────┼──────────┼────────┼────────────────────┼────────────┼─────────────────┼────────────╢
║3║ 10000 │ 36 │ 48 │ 5 │ 1360 │ 28 │ 16 ║
╚═╩═══════════╧══════════╧════════╧════════════════════╧════════════╧═════════════════╧════════════╝
```

After all you have the needed quantities and now you can combine them into one sentence easily.

```
=D2 & " full pallets, plus " & F2 & " extra full cases, plus " & G2 " extra units."
```

If you can't create hidden columns then the following formula can tell all things in one line, but as you can see now it's very unreadable and inefficient because many things will have to be calculated again and again

```
=QUOTIENT(A2, B2*C2) & " full pallets, plus " &
QUOTIENT(A2-QUOTIENT(A2, B2*C2)*C2*B2, C2) & " extra full cases, plus " &
MOD(A2-QUOTIENT(A2, B2*C2)*C2*B2, C2) & " extra units"
```