1

I have these two icons showing up in my system tray. I have Win10 Pro x64. Why are they there? How can I get rid of them, aside from simply not showing them? enter image description here

  • I have no idea how they got there. I just installed Win10 and I added the same programs that I had in Win7. I can't even find anyone that has seen them, and that is saying something. – david Mar 6 '17 at 21:30
  • If this is currently running, look in Task Manager’s Details tab for a process with the description “Main executable module”. Right-click on any header, go to the column selection and check both command line and image path. Please include those two in your question, if you can find the process. – Daniel B Mar 6 '17 at 21:36
  • Daniel B, you are a genius. I run an ooooold program called WatchCat. It lets me hide windows when people get too close. That is what was doing it. – david Mar 6 '17 at 21:43
  • Hi David. I tried to improve your title (other mods may tweak it later)--but remember titles are how other users here find your question (and helpful answers) later. Try to include more detail next time. Thanks! – PatKilg Mar 10 '17 at 15:37
0

The simplest solution to clear the binary data IconStreams and PastIconsStream located within HKEY_CURRENT_USER\SOFTWARE\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify

  1. Run the .bat script below
  2. Close and save anything that you are working on before proceeding. The next steps will involve killing explorer and restarting the PC.
  3. Run the .bat file.
  4. If prompted, click/tap on Run to approve. If you like, you can unblock the .bat file to no longer get the Run (Open File - Security Warning) prompt.
  5. Follow the instructions in the command prompt to reset your notification area icons. If you do not restart the PC now, you will need to later to finish resetting your notification area icons. (see screenshots below)

Source: How to Reset Notification Area Icons in Windows 10

Reset_Notification_Area_Icons_Cache

:: Created by: Shawn Brink
:: http://www.tenforums.com
:: Tutorial: http://www.tenforums.com/tutorials/5662-notification-area-icons-reset-windows-10-a.html


@echo off

set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream


echo.
echo The Explorer process must be temporarily killed before deleting your notification area icons cache. 
echo.
echo Please SAVE ALL OPEN WORK before continuing.
echo.
pause


echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
echo Registry key "IconStreams" already deleted.
echo.

:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto restart

:IconStreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream

:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"


:restart
echo.
echo.
echo You will need to restart the PC to finish resetting your notification area icons.
echo.
CHOICE /C:YN /M "Do you want to restart the PC now?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes


:no
echo.
echo.
echo Restarting explorer.... 
echo.
echo Please remember to restart the PC later to finish resetting your notification area icons.
echo.
start explorer.exe
pause
exit /B

:yes
shutdown /r /f /t 00
| improve this answer | |
  • Worth pointing out that at least one of those (Network) is suppose to be in your tray icons. – Ramhound Mar 6 '17 at 21:34

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.