4

Now I want to retrieve password of an old WiFi connection but when I run netsh wlan show profile command it shows

There is no such wireless interface on the system

I am able to connect to other WiFi network, I don't know what the problem is. Please help me to sort it out.

5 Answers 5

3

I am not sure why did you try to use netsh wlan show profile, but I think the easiest way would be following 2 steps.

  1. List all wireless network profiles: netsh wlan show profiles (note s at the end of profiles).

  2. Show key for specific profile : netsh wlan show profile name="Profile_Name" key=clear (this time it's profile without s).

See this article for more details.

1
  • 4
    And if you just want to see the line with the unencrypted key, you can pipe the results to the find command, e.g., netsh wlan show profile name="Profile_Name" key=clear | find "Key Content"
    – moonpoint
    Jun 18, 2017 at 0:18
2

The same problem happened to me. The problem was probably because the Wifi name had a space in between words, and if you know bits about programming, the systems are quite keen on spaces, so you never make a variable with space in between the words. To fix the problem, all you need to do is to tell the program that it's just a simple text and nothing else. And running.t has answered the solution, by adding [name="(text)"]. The system will just treat the text in the quoted text as text. Just explaining this in case you didn't know and for all the future readers that comes to this forum(was bored anyways, too).

For those who still don't get it, just do as running.t said:

netsh wlan show profile name="wifi name" key=clear

P.S.: For those that still don't work, the reasons are typically the following:

  • This code/command is for showing specific information(s) about the WiFi that you have access to or saved, so if you want to know the pass for a WiFi that doesn't belong to you or you don't have access to, simply break into a computer that is connected to the WiFi(and logged in as admin), although NEVER DO THIS, it's basically a crime depending on what you break into.

  • You have spelled wrongly. Make sure to check EVERY single letters that you see.

  • You didn't run the CMD program as an admin. Since showing passwords n' stuff r like "top secret" stuff, only admins are able to have access to the command(you can still use the command as a normal user, but the pass will NOT be revealed.) so make sure to right click and click on 'run as administrator' when you are hovering on the CMD program.

Hope this helped.

1
  • still tells me: Profile "(The Profile Name)" is not found on the system. Even though I straight copied the profile name and used quotes Jul 13, 2021 at 20:07
1

You have simply forgotten half the command used to reveal the Wi-Fi connection password.

First, to make sure you qualify for this command, check the following;

  1. The device that you are using to run this command must have already been connected to the Wireless Network before.

  2. You must be connected to the Wireless Network while executing the command.

  3. You might need administrative privileges when running the command, depending on your Group Policy on your device. You must also have access to the Command Prompt in the first place.

First Option: Open command prompt by searching "cmd" in either Cortana (Windows search bar) or in Run (Win + R). Write the command netsh wlan show profile "your wireless network" key=clear Be sure to change "your wireless network" accordingly. After writing the command, press Return or Enter keys to execute the command. Once executed, you will find the Security Key under Security Settings.

Second Option: Open "netsh" in either Cortana or Run and execute the command wlan show profile "your wireless network" key=clear Be sure to change "your wireless network" accordingly. After writing the command, press Return or Enter keys to execute the command. Once executed, you will find the Security Key under Security Settings.

Third Option: (On Windows 10) Go to Control Panel > Network and Internet > Network and Sharing Center. Select the Wi-Fi Network that you are connected to. On the screen that pops up, select "Wireless Properties". On the new pop-up screen, select the Security Tab, and under "Network Security Key", select the "Show Characters" box. (Note: You will need administrative privileges to perform this action.)

0

I experienced a similar issue but when I typed the name of the profile as a string with "", I was able to get through

1
  • Welcome to Super User! Before answering an old question having other answers please read all answers and ensure your answer adds something new or is otherwise helpful in relation to them. Here is a guide on How to Answer. There is also tour for the site tour, and help center for the help center. Feb 18, 2021 at 11:04
0

First : You should run this command with admin rights and don't forget to enclose the Profile Name with double quotes "Profile Name with Spaces" because the Profile Name can be with spaces !

netsh wlan show profile name="Profile Name" key=clear

I made before a batch script to in order to find and display all the SSID registered on a PC with their Key Passwords and save them into a text file.

Batch Version : Wifi_Passwords_Recovery.bat

@echo off & setlocal enabledelayedexpansion
Set "Copyright=by Hackoo 2017"
Title  %~n0 %Copyright%
Mode con cols=75 lines=8
cls & color 0A & echo.
    echo             ***********************************************
    echo                 %~n0 %Copyright%
    echo             ***********************************************
    echo(
if _%1_==_Main_  goto :Main
Set Count=0
Set L=0
:getadmin
    echo               %~nx0 : self elevating
    set vbs=%temp%\getadmin.vbs
(
    echo Set UAC = CreateObject^("Shell.Application"^)
    echo UAC.ShellExecute "%~s0", "Main %~sdp0 %*", "", "runas", 1
)> "%vbs%"
    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
goto :eof
::*************************************************************************************
:Main
Call :init
Call :CountLines
Set "PasswordLog=%~dp0Wifi_Passwords_on_%ComputerName%.txt"
%Mod%
    echo(
    echo             ***********************************************
    echo                 %~n0 %Copyright%
    echo             ***********************************************
    echo(
Call :Color 0E "                 [N][SSID] ================ Password" 1
echo(
(
    echo             ***********************************************
    echo                 %~n0 %Copyright%
    echo             ***********************************************
    echo(
    echo                  [N][SSID] ==============^> "Password"
    echo(
    
)>"%PasswordLog%"
for /f "skip=2 delims=: tokens=2" %%a in ('netsh wlan show profiles') do (
    if not "%%a"=="" (
        set "ssid=%%a"
        set "ssid=!ssid:~1!"
        call :Getpassword "!ssid!"
    )
)
echo(
echo Done
If exist "%PasswordLog%" start "" "%PasswordLog%"
pause>nul
exit
::*************************************************************************************
:Getpassword
set "name=%1"
set "name=!name:"=!"
Set "passwd="
for /f "delims=: tokens=2" %%a in ('netsh wlan show profiles %1 key^=clear ^|find /I "Cont"') do (
    set "passwd=%%a"
    Set /a Count+=1
)

If defined passwd (
    set passwd=!passwd:~1!
    echo                  [!Count!][!name!] ====^> "!passwd!"
    echo                  [!Count!][!name!] ====^> "!passwd!" >> "%PasswordLog%"
) else (
    Set /a Count+=1
call :color 0C "                 [!Count!][!name!] The Password is empty" 1
    echo                  [!Count!][!name!] The Password is empty >> "%PasswordLog%"
)
exit /b
::*************************************************************************************
:init
prompt $g
for /F "delims=." %%a in ('"prompt $H. & for %%b in (1) do rem"') do set "BS=%%a"
exit /b
::*************************************************************************************
:color
set nL=%3
if not defined nL echo requires third argument & pause > nul & goto :eof
if %3 == 0 (
    <nul set /p ".=%bs%">%2 & findstr /v /a:%1 /r "^$" %2 nul & del %2 2>&1 & goto :eof
) else if %3 == 1 (
    echo %bs%>%2 & findstr /v /a:%1 /r "^$" %2 nul & del %2 2>&1 & goto :eof
)
exit /b
::*************************************************************************************
:CountLines
for /f "skip=2 delims=: tokens=2" %%a in ('netsh wlan show profiles') do (
    if not "%%a"=="" (
        set /a L+=1
    )
)
set /a L=!L! + 10
Set Mod=Mode con cols=75 Lines=!L!
exit /b
::*************************************************************************************

Autoit Version : Wifi Passwords Recovery.au3


Vbscript version : Wifi Passwords Recovery.vbs


HTA Version : Wifi Passwords Recovery.hta


Github - Windows-Wifi-Recovery

enter image description here

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .