2

In case where you are fullscreen, doing some work and suddenly have to jump to the taskbar to switch to another program or to use a utility which resides in system tray menu. Pressing Start or Ctrl+Esc shows the taskbar with start menu open. The opened start menu is somewhat distractive when you are doing some focus-oriented tasks such as programming.

So, are there any ways to achieve this? Any tweaks? Any registry edits?

PS. I have tried many utilities such as 7+ Taskbar Tweaker but got nothing to work!

1
  • Press Windows+T to focus on the apps
  • Press Windows+B to focus on the notification area

Both will show the taskbar without the start menu

0

Press ALT key, twice to show the taskbar without start menu. To achieve this, we need to use autohotkey.

Using the Rapidhotkey function, send Win key + B, to activate taskbar without start menu. Set the number of clicks required (2), and the time allowed between clicks (0.3).

~Alt::RapidHotkey("myLabel", 2, 0.3, 1)

myLabel:
    Send #b
Return

To use the RapidHotkey function, include the 2 functions below in your script. Copy pasted below for your convenience. Details in Autohotkey forums.

; Rapid hotkey library
RapidHotkey(keystroke, times="2", delay=0.2, IsLabel=0)
{
    Pattern := Morse(delay*1000)
    If (StrLen(Pattern) < 2 and Chr(Asc(times)) != "1")
        Return
    If (times = "" and InStr(keystroke, """"))
    {
        Loop, Parse, keystroke,""   
            If (StrLen(Pattern) = A_Index+1)
                continue := A_Index, times := StrLen(Pattern)
    }
    Else if (RegExMatch(times, "^\d+$") and InStr(keystroke, """"))
    {
        Loop, Parse, keystroke,""
            If (StrLen(Pattern) = A_Index+times-1)
                times := StrLen(Pattern), continue := A_Index
    }
    Else if InStr(times, """")
    {
        Loop, Parse, times,""
            If (StrLen(Pattern) = A_LoopField)
                continue := A_Index, times := A_LoopField
    }
    Else if (times = "")
        continue := 1, times := 2
    Else if (times = StrLen(Pattern))
        continue = 1
    If !continue
        Return
    Loop, Parse, keystroke,""
        If (continue = A_Index)
            keystr := A_LoopField
    Loop, Parse, IsLabel,""
        If (continue = A_Index)
            IsLabel := A_LoopField
    hotkey := RegExReplace(A_ThisHotkey, "[\*\~\$\#\+\!\^]")
    IfInString, hotkey, %A_Space%
        StringTrimLeft, hotkey,hotkey,% InStr(hotkey,A_Space,1,0)
    backspace := "{BS " times "}"
    keywait = Ctrl|Alt|Shift|LWin|RWin
    Loop, Parse, keywait, |
        KeyWait, %A_LoopField%
    If ((!IsLabel or (IsLabel and IsLabel(keystr))) and InStr(A_ThisHotkey, "~") and !RegExMatch(A_ThisHotkey
    , "i)\^[^\!\d]|![^\d]|#|Control|Ctrl|LCtrl|RCtrl|Shift|RShift|LShift|RWin|LWin|Alt|LAlt|RAlt|Escape|BackSpace|F\d\d?|"
    . "Insert|Esc|Escape|BS|Delete|Home|End|PgDn|PgUp|Up|Down|Left|Right|ScrollLock|CapsLock|NumLock|AppsKey|"
    . "PrintScreen|CtrlDown|Pause|Break|Help|Sleep|Browser_Back|Browser_Forward|Browser_Refresh|Browser_Stop|"
    . "Browser_Search|Browser_Favorites|Browser_Home|Volume_Mute|Volume_Down|Volume_Up|MButton|RButton|LButton|"
    . "Media_Next|Media_Prev|Media_Stop|Media_Play_Pause|Launch_Mail|Launch_Media|Launch_App1|Launch_App2"))
        Send % backspace
    If (WinExist("AHK_class #32768") and hotkey = "RButton")
        WinClose, AHK_class #32768
    If !IsLabel
        Send % keystr
    else if IsLabel(keystr)
        Gosub, %keystr%
    Return
}   
Morse(timeout = 400) { ;by Laszo -> http://www.autohotkey.com/forum/viewtopic.php?t=16951 (Modified to return: KeyWait %key%, T%tout%)
   tout := timeout/1000
   key := RegExReplace(A_ThisHotKey,"[\*\~\$\#\+\!\^]")
   IfInString, key, %A_Space%
        StringTrimLeft, key, key,% InStr(key,A_Space,1,0)
    If Key in Shift,Win,Ctrl,Alt
        key1:="{L" key "}{R" key "}"
   Loop {
      t := A_TickCount
      KeyWait %key%, T%tout%
        Pattern .= A_TickCount-t > timeout
        If(ErrorLevel)
            Return Pattern
    If key in Capslock,LButton,RButton,MButton,ScrollLock,CapsLock,NumLock
      KeyWait,%key%,T%tout% D
    else if Asc(A_ThisHotkey)=36
        KeyWait,%key%,T%tout% D
    else
      Input,pressed,T%tout% L1 V,{%key%}%key1%
    If (ErrorLevel="Timeout" or ErrorLevel=1)
        Return Pattern
    else if (ErrorLevel="Max")
        Return
   }
}
-1

Would doing Start+D (Windows key+D) be useful maybe? This brings you to your desktop, and minimizes everything. It takes me out of fullscreen... at least, youtube fullscreen. Not sure about other programs.

2
  • Thanks. I do know about Start+D. Yes, this key combo is global thus works for all the Windows programs .
    – bantya
    Aug 11 '18 at 15:02
  • does not answer the question
    – tinker
    Apr 27 at 2:17

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.