How to sort number of numeric columns in one go

Question

I have 350 columns. Below is a subset of all the data.

I used "Sort Smallest to Largest" tool. It gives results only for one column. If not, it can sort the first column and other columns will change according to the first one. But I want to sort all columns A-Z separately.

I want to sort the data by district.

Answer 1

1. Select the column you want to sort. Then click on "Sort Smallest to Largest".

2. Choose "Continue with the current selection".

You can see, only one column was sorted.

Repeat this for the rest 349 columns :)

---

In order to do it alltogether in one go:

1. Open the sheet you want to sort.

2. Open VBA editor using Alt+F11

3. Insert > Module

4. Paste this code:

Sub sort_columns_separately_AZ()
  Dim rngStart As Range
  Dim rngHeaders As Range
  Dim c As Range
  Set rngStart = ActiveSheet.Range("A2")
  Set rngHeaders = ActiveSheet.Range(rngStart, rngStart.End(xlToRight))

  For Each c In rngHeaders
    ActiveSheet.Sort.SortFields.Clear
    ActiveSheet.Sort.SortFields.Add Key:=c, _
      SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With ActiveSheet.Sort
      .SetRange ActiveSheet.Range(c, c.End(xlDown))
      .Header = xlYes
      .MatchCase = False
      .Orientation = xlTopToBottom
      .SortMethod = xlPinYin
      .Apply
    End With
  Next
End Sub

5. In the code, change ActiveSheet.Range("A2") with the cell address where your data table starts, for example ActiveSheet.Range("B5") .
6. Hit F5

Results:

Note: if you have any empty cells in your data, this code will need adjustments in order to work correctly on those columns which have empty cells.