1

Is there possibly a way/software(built in is preffered) in windows 10 without "permanently" adjust the default scroll settings but temporary increase scrolling to double the speed by for example holding in an button.

I love my default settings on scroll, but sometimes i really wish i maybe could hold in a button to get super speed temporary to scroll through a big list.

Very few programs such as vscode has this built in, i think by holding "alt" key you get fast scrolling there but i would appreciate a more universal working method for whole windows 10.

2 Answers 2

3

The following AutoHotkey script will accelerate wheel scroll by a factor of three when Shift is pressed while scrolling:

$+WheelUp::          ; "$" for physical wheel event, not when sent as below
    Send {WheelUp 3} ; The 3 means "Send 3 times" and can be altered
    return

$+WheelDown::
    Send {WheelDown 3}
    return

Place the script in an .ahk file. Test by double-click to launch. It will have a green "H" icon in the traybar, which you may right-click to Exit. Once proven as working correctly, you may place it in your Startup folder.

0

Here is an updated version of @harrymc's answer which works with AutoHotkey v2. I also added the ability to ignore certain applications:

#Requires AutoHotkey v2.0
#SingleInstance Force

; Array of windows to ignore
ignoredWindows := ["ahk_exe code.exe", "ahk_exe code_ignore.exe", "ahk_exe minecraftlauncher.exe", "ahk_exe minecraft.exe"]

; Function to check if any of the specified windows is active
IsIgnoredWindowActive() {
    for window in ignoredWindows {
        if (WinActive(window))
            return true
    }
    return false
}

; Special Keys: https://autohotkey.com/docs/Hotkeys.htm
; ! = alt
; + = shift
; ^ = ctrl
; # = win
$!WheelUp::
{
    if (!IsIgnoredWindowActive()) {
        Send("{WheelUp 5}")
    }
    return
}

$!WheelDown::
{
    if (!IsIgnoredWindowActive()) {
        Send("{WheelDown 5}")
    }
    return
}

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .