findstr: How to escape the dot?

Question

I don't understand why findstr doesn't work as I want.

I have the following files in my test directory:

aaa.jpg
bbb.png
ccc.svg

aaa_s.jpg
bbb_s.png
ccc_s.svg

aaa_small.jpg
bbb_small.png
ccc_small.svg

And I have the following line to pass directly to cmd.exe:

for /f "delims=" %f in ('dir /b /a:-d ^| findstr /ile "gif jpg png svg" ^| findstr /ie "_s.*"') do echo "%f"

To my opinion, it should match the following files:

aaa_s.jpg
bbb_s.png
ccc_s.svg

However, it's actually matches

aaa_s.jpg
bbb_s.png
ccc_s.svg

aaa_small.jpg
bbb_small.png
ccc_small.svg

Yes, I understand that the problem is that the dot works as "any character" instead of being treated literally.

findstr /ie "_s.*"

Bot how can I escape it? Using backslash, i.e. changing it to

findstr /ie "_s\.*"

doesn't work.

Answer 1

How can I escape the wildcard . in order to match a literal . character?

You are on the right lines with using a \, however you need an additional . in order to find the remaining characters.

findstr /ie "_s\..*"

Example (type and a cmd shell):

F:\test>dir /b /a:-d | findstr /ile "gif jpg png svg" | findstr /ie "_s.*"
aaa_s.jpg
bbb_s.jpg
ccc_s.jpg
aaa_small.jpg
bbb_small.jpg
ccc_small.jpg

F:\test>dir /b /a:-d | findstr /ile "gif jpg png svg" | findstr /ie "_s\..*"
aaa_s.jpg
bbb_s.jpg
ccc_s.jpg

So your batch file should contain:

for /f "delims=" %f in ('dir /b /a:-d ^| findstr /ile "gif jpg png svg" ^| findstr /ie "_s\..*"') do echo "%f"

Answer 2

For this specific task you can also escape the "." in the findstr by not using it if you replace:

dir /b /a:-d → where .:*_s.*

findstr /ie "_s\.*" → findstr /ei "gif jpg png svg"

where .:*_s.*|findstr /ei  "gif  jpg  png  svg"

for /f delims^= %f in ('where .:*_s.*^|findstr /ei  "gif  jpg  png  svg"')do echo "%~nxf"