22

I'm looking for a way, via terminal, to change whether or not a specific file's extension is shown in the Finder, something along the lines of:

$ hideextension ~/music/somesong.mp3

Without having to open Get Info and change the checkbox, as it's massively tedious.

I plan on incorporating it into a script I'm calling via a shortcut using FastScripts. I'd like to try and stay away from GUI scripting as that feels unclean, although any ideas on how to accomplish this are welcome.

  • If it makes any difference, I'm trying to accomplish this on Lion. – joshua.thomas.bird Mar 12 '12 at 20:18
25

The only real way to change this via GUI is to click Hide extension in the Finder Info window. Checking this changes the com.apple.FinderInfo extended attribute, which you normally can't edit – at least not easily. We can however use a tool to do it for us.

For the below to work, you obviously need to have Show all file extensions unchecked in Finder's preferences.


Through AppleScript

AppleScript offers this functionality with the set extension hidden command. You obviously need an alias to a file object. We can get that, for example, though a dialog. Here's just a minimal working example.

tell application "Finder"
    set some_file to (choose file)
    set extension hidden of some_file to true
end tell

To reverse, just exchange true with false here. The full call is then, for example:

set extension hidden of alias "Macintosh HD:Users:werner:Desktop:file.png" to true

You can run this straight from a script file too (thanks @DanielBeck for the addition):

on run argv
tell application "Finder" to set extension hidden of (POSIX file (first item of argv) as alias) to true
end run

Save this as filename.scpt and run it from the command line with:

osascript filename.scpt targetfile

With the SetFile command

Note: This is deprecated since Xcode 6.

If you have Xcode installed, you will get the SetFile(1) binary, which does exactly what you want (and offers a few more functions related to file attributes):

Hide extension:

SetFile -a E <file>

Show extension again:

SetFile -a e <file>
| improve this answer | |
  • Strictly speaking, it's an alias, not a file. Here's how to use the AppleScript from the command line: on run argv [newline] tell application "Finder" to set extension hidden of (POSIX file (first item of argv) as alias) to true [newline] end run, use as osascript filename.scpt targetfile. – Daniel Beck Mar 12 '12 at 21:45
  • 1
    You're right, of course. I added the full AppleScript event. In the future, just go ahead and add anything important to the answer – you're always welcome to. – slhck Mar 12 '12 at 21:50
  • 1
    just what I was looking for.. thankfully I have Xcode installed and SetFile did the trick :-) – thandasoru Oct 2 '13 at 13:42
  • SetFile is deprecated since Xcode 6. Also the link to manual page has expired. – Franklin Yu Nov 8 '18 at 5:25
  • @FranklinYu Thanks for the info. Do you know of a replacement? – slhck Nov 8 '18 at 7:19
5

Thanks slhck for your Answer, it helped me a bunch to get what I wanted done.

So since I like shortcuts, I created a "Run Shell Script" Service though Automator.

for f in "$@"
do
    STATUS=`getFileInfo -ae "$f"`
    if [ $STATUS== 0 ];
    then
        SetFile -a E "$f"
    else
        SetFile -a e "$f"
    fi
done

Then I went to Finder -> Services Preferences and added a shortcut to the Service.

 "Command + Shift + H" didn't work for me,
 "Command + H" hides the application
 so i chose "Command + Shift + E"

Hope it helps. =)

| improve this answer | |
  • The STATUS= line is missing a back-tick at the end. Also, on my Mac + XCode, the command GetFileInfo has a capital G. – bjnord Mar 3 '15 at 1:25
1

There is one more option if you want to show file extension that is currently hidden: Finder stores this "hide extension" option in com.apple.FinderInfo extended file attribute. You can check it yourself by running this command which lists all extended attributes:

xattr -l /path/to/the/file

So, in order to show the extension, you can remove that attribute:

xattr -d com.apple.FinderInfo /path/to/the/file

But keep in mind that Finder stores other metadata such as tag color in this attribute, so this metadata will be lost. And, since the attribute is binary, you cannot easily modify it.

| improve this answer | |
0

In order to have only one argument on the command line ($ hideextension ~/music/somesong.mp3), you can make your applescript become a shell script. It is possible to use osascript in the shebang (#!/usr/bin/osascript) like in the following code. To proceed :

  1. Test your applescript code in a .scpt file => toggle_hidden_extension.scpt
  2. When OK, add the shebang (#!/usr/bin/osascript) at the beginning of the file
  3. Export it with file format "text" => toggle_hidden_extension.applescript
  4. Change extension to .sh => toggle_hidden_extension.sh
  5. In Terminal, make it executable :

    chmod u+x toggle_hidden_extension.sh
    
  6. Now you can run it :

    ./toggle_hidden_extension.sh /path/to/myfile.mp3
    

So, the code to illustrate:

#!/usr/bin/osascript

(*
usage: toggle_hidden_extension.sh file
*)

(*
Test 1 : ./toggle_hidden_extension.sh /Users/boissonnfive/Desktop/file.txt
Test 2 : ./toggle_hidden_extension.sh
Test 3 : ./toggle_hidden_extension.sh 0fdjksl/,3
*)

on run argv
    try
        processArgs(argv)
        toggleHiddenExtension(item 1 of argv)
    on error
        return usage()
    end try

    if result then
        return "Extension hidden for " & POSIX path of (item 1 of argv)
    else
        return "Extension revealed for " & (POSIX path of (item 1 of argv))
    end if

end run


on usage()

    return "usage: toggle_hidden_extension.sh file"

end usage

on processArgs(myArgs)

    set item 1 of myArgs to POSIX file (first item of myArgs) as alias

end processArgs

on toggleHiddenExtension(myFile)

    tell application "Finder" to set extension hidden of myFile to not (extension hidden of myFile)

end toggleHiddenExtension
| improve this answer | |
0

Even if SetFile is deprecated since Xcode 6 it’s still available in XCode 11, so you can expect it to remain in the Command Line Tools for the foreseable future...

https://download.developer.apple.com/Developer_Tools/Command_Line_Tools_for_Xcode_11/Command_Line_Tools_for_Xcode_11.dmg

$ pkgutil --payload-files /Volumes/Command\ Line\ Developer\ Tools/Command\ Line\ Tools.pkg | grep SetFile
./Library/Developer/CommandLineTools/usr/bin/SetFile
./Library/Developer/CommandLineTools/usr/share/man/man1/SetFile.1
| improve this answer | |

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.