I'm working with a number of data lists that are keyed by document name. The document names, while very descriptive, are quite cumbersome if I need to view them on (up to 256 bytes is a lot of real estate) and I'd love to be able to create a smaller keyfield that's readily reproducible in case I need to do a VLOOKUP from another workseet or workbook.

I'm thinking a hash from the title that'd be unique and reproducible for each title would be most appropriate. Is there a function available, or am I looking at developing my own algorithm?

Any thoughts or ideas on this or another strategy?


You don't need to write your own function - others already did that for you.
For example I collected and compared five VBA hash functions on this stackoverflow answer

Personally I use this VBA function

  • its called with =BASE64SHA1(A1) in Excel after you copied the macro to a VBA module
  • requires .NET since it uses the library "Microsoft MSXML" (with late binding)

Public Function BASE64SHA1(ByVal sTextToHash As String)

    Dim asc As Object
    Dim enc As Object
    Dim TextToHash() As Byte
    Dim SharedSecretKey() As Byte
    Dim bytes() As Byte
    Const cutoff As Integer = 5

    Set asc = CreateObject("System.Text.UTF8Encoding")
    Set enc = CreateObject("System.Security.Cryptography.HMACSHA1")

    TextToHash = asc.GetBytes_4(sTextToHash)
    SharedSecretKey = asc.GetBytes_4(sTextToHash)
    enc.Key = SharedSecretKey

    bytes = enc.ComputeHash_2((TextToHash))
    BASE64SHA1 = EncodeBase64(bytes)
    BASE64SHA1 = Left(BASE64SHA1, cutoff)

    Set asc = Nothing
    Set enc = Nothing

End Function

Private Function EncodeBase64(ByRef arrData() As Byte) As String

    Dim objXML As Object
    Dim objNode As Object

    Set objXML = CreateObject("MSXML2.DOMDocument")
    Set objNode = objXML.createElement("b64")

    objNode.DataType = "bin.base64"
    objNode.nodeTypedValue = arrData
    EncodeBase64 = objNode.text

    Set objNode = Nothing
    Set objXML = Nothing

End Function

Customizing the hash length

  • the hash initially is a 28 characters long unicode string (case sensitive + special chars)
  • You customize the hash length with this line: Const cutoff As Integer = 5
  • 4 digits hash = 36 collisions in 6895 lines = 0.5 % collision rate
  • 5 digits hash = 0 collisions in 6895 lines = 0 % collision rate

There are also hash functions (all three CRC16 functions) which doesn't require .NET and doesn't use external libraries. But the hash is longer and produces more collisions.

You could also just download this example workbook and play around with all 5 hash implementations. As you see there is a good comparison on the first sheet

  • 1
    Looks great. However, I don't have enough VBA experience to prevent Excel from returning #NAME?. View code > cut and paste code into new window -- within the correct worksheet in the navigator > save as macro-enabled worksheet > close and return to excel...anything else I'm missing? Do I need to compile it somehow? – dwwilson66 Feb 13 '13 at 16:09
  • Yes...to clarify...i pasted it in the new code window that popped up when I went to worksheet tab > view code... Downloading the sample right now, but I would like to understand why excel doesnt recognize my code – dwwilson66 Feb 13 '13 at 16:54
  • WooHoo...the sample sheet helped. Realized I'd pasted the code into and excel OBJECT window, not a MODULE window. I'm getting hashes in my workbook now! – dwwilson66 Feb 13 '13 at 17:03
  • 1
    This is an excellent tool. – Jay Killeen Aug 23 '15 at 14:48
  • 1
    You can make the cutoff parameterized and optional with a different default by moving it up to the Function parameter list Public Function BASE64SHA1(ByVal sTextToHash As String, Optional ByVal cutoff As Integer = 8) and remove the declaration inside the function. – Core Mar 7 '19 at 22:08

I don't care very much about collisions, but needed a weak pseudorandomizer of rows based on a variable-length string field. Here's one insane solution that worked well:


Where Z2 is the cell containing the string you want to hash.

"MOD"s are there to prevent overflowing to scientific notation. 1009 is a prime, could use anything X so that X*255 < max_int_size. 10 is arbitrary; use anything. "Else" values are arbitrary (digits of pi here!); use anything. Location of characters (1,3,5,7,9) are arbitrary; use anything.

  • 3
    Honestly this is the simplest answer, I doubt collisions are an issue for most excel use cases. – rolls Aug 1 '18 at 1:52

For a reasonably small list you can create a scrambler (poor man's hash function) using built-in Excel functions.


 =CODE(A2)*LEN(A2) + CODE(MID(A2,$A$1,$B$1))*LEN(MID(A2,$A$1,$B$1))

Here A1 and B1 hold a random start letter and string length.

A little fiddling and checking and in most cases you can get a workable unique ID quite quickly.

How it Works: The formula uses the first letter of the string and a fixed letter taken from mid-string and uses LEN() as a 'fanning function' to reduce the chance of collisions.

CAVEAT: this is not a hash, but when you need to get something done quickly, and can inspect the results to see that there are no collisions, it works quite well.

Edit: If your strings should have variable lengths (e.g. full names) but are pulled from a database record with fixed width fields, you will want to do it like this:


so that the lengths are a meaningful scrambler.

  • 1
    Great answer! (: "poor man's hash function", "caveat", "how it works" :) – nutty about natty Aug 8 '18 at 8:11
  • 1
    To "inspect the results to see that there are no collisions" you could simply try / test this by running DATA > REMOVE DUPLICATES and see if there are any. [obviously / presumably, if you do encouter duplicates you could just re-run the above function for these iteratively until no duplicates are left] – nutty about natty Aug 8 '18 at 8:15

I am using this which gives pretty good results with preventing clashing without needing to run a script each time. I needed a value between 0 - 1.


It picks letters from across the string, takes the value of each of those letters, adds a value (to prevent same letters in different places giving same results), multiplies/divides each and runs a COS function over the total.


You can try this. Run a Pseudo# on two columns:


Where A1 and B1 store random seeds entered manually: 0


To my knowledge there is no hash function build into Excel - you'd need to build one as a User Defined Function in VBA.

However, please note that for your purpose I don't think using a hash is required or really advantageous! VLOOKUP will work just as well on 256 bytes as it'll be on a smaller hash. Sure, it might be a tiny bit slower - bit that is for sure so small that it is immeasurable. And then adding the hash values is more effort for you - and for Excel...

  • yeah...I know that, but just from a presentation standpoint, I'd rather display, say, 15 bytes of hash that 256 bytes of title in my frozen left pane... – dwwilson66 Feb 13 '13 at 15:11

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.