Command line - Some questions

Question

I've created a batch file for zipping selected items in a folder. (The file is placed in 'Send to').

If I use the following code:

for %%* in (.) do set CurrentFolder=%%~n* "C:\Program Files\WinRar\WinRar" a -afzip "%CurrentFolder%.xpi"

• The file name is that of the current folder (correct).
• All files are archived whether I select one file or multiple files (wrong).
• Selected folders are not archived (wrong).

If I use the following code:

set file=%~f1 "C:\Program Files\WinRar\WinRar" a -afzip "%file:~0,-4%.xpi" %1

• The file name is that of the file on which I right click (correct).
• Only that file is archived even if multiple files are selected (wrong).

How can I know if a single item is selected or more?

What's the condition syntax?

How can I include folders in the archive?

Thank you.

Answer 1

This should help you some...

@echo off
::Save passed parameter to a variable...
set _loc=%~1

::Check if passed parameter is a file/folder and process accordingly...
if exist "%~s1\*" (echo Processing all files in folder %_loc% && echo. && goto :ProcFolders) else (echo Processing files && echo. && goto :ProcFile)
goto :exit

::When passed parameter is a folder...
:ProcFolders
::Check if folder is empty...
dir /b /a:-d "%_loc%" >nul 2>&1 && (echo  Non-empty folder!) || (echo Checking for sub-folders... && goto :CheckSubDir)

:CheckSubDir
dir /b /a:-d /s "%_loc%\*">nul 2>&1 && (echo. && echo Subfolders/files exist) || (echo. && echo No file or subfolders found && goto :exit)

::If folder has files or subfolders with files, continue here.
for /f %%g in ('dir /b /a:-d /s "%_loc%\*.*"') do echo Processing %%g &&    echo.
goto :exit

::When passed parameter is a file...
:ProcFile
if "%~1"=="" goto :exit
echo Processing %~1 && echo.
shift
goto :ProcFile
goto :exit

:exit
pause
exit /b

The script checks if the passed parameter is a folder or individual files. If files, it will shift through the passed parameters and process each file individually. Be aware that you may hit a limitation in the number of characters that can be passed as an argument from the command prompt or drag and drop, so if a lot of files need to be processed, just process the entire folder. I've been able to pass 50+ files without a problem, but their names were relatively short. I've modified the script further to check for sub-directories as well.

Hope it helps!