I am running preinstalled Windows 7 Home Premium (Nordic, in Finnish for me). My C:\ folder of course has the Users folder, but its name is in Finnish.

Folder name

Clicking on the folder name in Explorer shows the real name.

Real folder name

This one is also the one showed by other applications, like the Web browser or 7-Zip.

This is not limited to C:\Users but also applies to Start Menu etc.

What I'd like to do is to turn off this localization in Explorer. Is there a way to do this?

up vote 15 down vote accepted

Folder customization

Folders are normally displayed with the standard folder icon. A common use of the Desktop.ini file is to assign a custom icon or thumbnail image to a folder. You can also use Desktop.ini to create an infotip that displays information about the folder and controls some aspects of the folder's behavior, such as specifying localized names for the folder or items in the folder.

Source: How to Customize Folders with Desktop.ini

Before the shell displays the name of a directory, the shell looks for a Desktop.ini file. If it finds one, it displays a redirected name obtained from LocalizedReourceName to the end user.

Source: Customizing Folders with Desktop.ini (Windows CE 5.0)

Here's the default content of the desktop.ini file stored in the C:\Users folder:

[.ShellClassInfo]
LocalizedResourceName=@%SystemRoot%\system32\shell32.dll,-21813

Disabling localized names

Windows Explorer doesn't seem to provide any documented way to ignore folder localization, but removing the LocalizedResourceName line does the job. While you could also delete the file entirely, it's not a good idea as you would lose other customization settings such as icons or tooltips.

Batch automation

Below there's a simple batch script which can do that for you, recursively scanning every folder in the system drive. Make sure to run it as administrator.

@echo off
setlocal enabledelayedexpansion

pushd "%systemdrive%\"

for /f "delims=" %%G in ('dir /a /b /s desktop.ini') do (
find /i "LocalizedResourceName=" "%%~G" >nul
if !errorlevel! == 0 (
takeown /f "%%~G" /a >nul
icacls "%%~G" /grant:r *S-1-5-32-544:F /q >nul
attrib -h -s "%%~G"
type "%%~G" | findstr /i /v /c:"LocalizedResourceName=" > "%%~G.new"
copy "%%~G" "%%~nxG.bak" >nul 2>&1
del /a "%%~G"
ren "%%~G.new" "%%~nxG"
attrib +h +s "%%~G.bak"
attrib +h +s "%%~G"
))

popd
pause & exit /b
  • 2
    thank you sir, you really save my day, I couldn't stand the inconsistency of my folders name – Kiwy Aug 13 '14 at 14:01
  • 3
    Wouldn't it be even better to comment the line out with ;? – SamB Nov 21 '14 at 2:02

The translation is controlled by a hidden file called desktop.ini. Open the Windows Explorer options, make sure you activate the option to show hidden and system files, now go into the folders, where you don't want to have a translation, and delete the ini file.

Your Answer

By clicking "Post Your Answer", you acknowledge that you have read our updated terms of service, privacy policy and cookie policy, and that your continued use of the website is subject to these policies.

Not the answer you're looking for? Browse other questions tagged or ask your own question.