How zoom in and out with a keyboard shortcut in MS Word 2013?

Question

I want to avoid using the mouse, touchpad or moving cursor to the down right corner "ruler" but I could not find a keyboard shortcut to Zoom in/out in a crecendo and decrecendo way. The only one I found is "Zoom100" but that is not what I'm looking for.

Is there a way to do this with a MS macro or using autohotkey?

Answer 1

AFAIK there's no keyboard shortcuts specifically for zooming.

Instead, create these two new VBA routines (macros):

Sub MyZoomIn()
  Dim iZoom As Long
  iZoom = ActiveWindow.View.Zoom
  iZoom = iZoom + 5
  ActiveWindow.View.Zoom = iZoom
End Sub

Sub MyZoomOut()
  Dim iZoom As Long
  iZoom = ActiveWindow.View.Zoom
  iZoom = iZoom - 5
  ActiveWindow.View.Zoom = iZoom
End Sub

Source

Then assign keyboard shortcuts to them:

1. Click the File tab.

2. Click Options.

3. Click Customize Ribbon, and then click Customize.

4. In the Save changes in box, click the current document name or template that you want to save the keyboard shortcut changes in.

5. In the Categories box, click the category that contains the command or other item that you want to assign a keyboard shortcut to or remove a keyboard shortcut from.

6. In the Commands box, click the name of the command or other item that you want to assign a keyboard shortcut to or remove a keyboard shortcut from.

   Any keyboard shortcuts that are currently assigned appear in the Current keys box.

7. Assign a keyboard shortcut:

   a. Begin keyboard shortcuts with CTRL or a function key.

   b. In the Press new shortcut key box, press the combination of keys that you want to assign. For example, press CTRL plus the key that you want to use.

   c. Look at Currently Assigned to see if the combination of keys is already assigned to a command or other item. If so, select a different combination.

   d. Click Assign.

Source

Answer 2

I would take TECHIE007's answer a step further, by adding the following code to a module in Normal.dotm:

Const FineZoom As Double = 5
Const CoarseZoom As Double = 25
Const MaxZoom As Double = 500
Const MinZoom As Double = 10

Sub ZoomInFine()
    With ActiveWindow.View
        If .Zoom <= (MaxZoom - FineZoom) Then .Zoom = .Zoom + FineZoom
    End With
End Sub

Sub ZoomOutFine()
    With ActiveWindow.View
        If .Zoom >= (MinZoom + FineZoom) Then .Zoom = .Zoom - FineZoom
    End With
End Sub

Sub ZoomInCoarse()
    With ActiveWindow.View
        If .Zoom <= (MaxZoom - CoarseZoom) Then .Zoom = .Zoom + CoarseZoom
    End With
End Sub

Sub ZoomOutCoarse()
    With ActiveWindow.View
        If .Zoom >= (MinZoom + CoarseZoom) Then .Zoom = .Zoom - CoarseZoom
    End With
End Sub

To do this, open a blank document in Word, and then:

1. Open the VBA Editor by pressing Alt+F11
2. Find "Normal" in the Project Explorer, right-click, then select 'Insert' and 'Module'

3. Copy and paste the above code into the newly-created, blank code module.
4. Save the VBA code (Ctrl+S) and close the VBA Editor

Using TECHIE007's instructions, I then would bind:

• ZoomInCoarse to Ctrl+Shift+Numpad +
• ZoomOutCoarse to Ctrl+Shift+Numpad -
• ZoomInFine to Ctrl+Alt+Shift+Numpad +
• ZoomOutFine to Ctrl+Alt+Shift+Numpad -

This form of the code allows a tunable rate of zoom, with automatic detection of zoom limits to avoid VBA runtime errors. If the fine and/or coarse zoom rates, or the zoom limits, are not to one's liking, they can readily be changed.

The behavior could be further customized by, e.g., adding macros that set particular favorite levels of zoom and binding shortcut keys.

Answer 3

I assume if you can try magnifier keys such as [windows button] + '+' for zoom in and [windows button] + '-' (minus sign) for zoom out in word doc...