When I double click files of the type .xise, I need my system to execute the following:

C:\Xilinx\14.5\ISE_DS\settings32.bat C:\Xilinx\14.5\ISE_DS\ISE\bin\nt\ise.exe PATH\TO\XISE\FILE\filename.xise

When I set its default behavior to open with the "settings32.bat" file (via Right Click > Properties > Opens With: > Change), I'm pretty sure it doesn't include the necessary "ise.exe" file (the first argument to the .bat file).

However, the default which maps to settings64.bat in the same directory works fine and I don't know what the installer did to map it correctly. (well, the x64 version doesn't "work". It's bugged and broken but for different reasons hence the desire to use the 32 bit version.)

There is nothing in the "settings64.bat" file that isn't in the "settings32.bat" file (just a few spots where 64 changes to 32), so it isn't the case that the "settings64.bat" file just doesn't need the "ise.exe" file; it does need it but I just don't know how to insert it correctly.

I've searched all around and I can't seem to figure out what to search in order to resolve this problem.



As you say: "... but for different reasons hence the desire to use the 32 bit version".

  • How-to find out default action for your .xise file:

From a batch script:

assoc .xise
for /F "tokens=2 delims==" %%G in ('assoc .xise') do (
      for /f "tokens=*" %%I in ('ftype %%G') do echo %%I

Or, to run for command from command line:

for /F "tokens=2 delims==" %G in ('assoc .xise') do for /f "tokens=*" %I in ('ftype %G') do echo %I

  • How-to re-establish default action for your .xise file

(from a batch script, need to be run as administrator):

::  discover the association between our file Extension and current file Type
set "xiseFileType=xiseFile"
for /F "tokens=2 delims==" %%G in ('assoc .xise') do set "xiseFileType=%%G"

:: set variables for better readability next 'ftype' command
set "batchToRun=C:\Xilinx\14.5\ISE_DS\settings32.bat"
set "bat1stPar=C:\Xilinx\14.5\ISE_DS\ISE\bin\nt\ise.exe"

:: define 'cmd.exe' full path: 
:: default version (32-bit or 64-bit dependent on Windows version installed): 
set "com32exe=%comspec%"

:: but we need (non-default) 32-bit version of command interpreter:
if exist "C:\Windows\SysWOW64\cmd.exe" set "com32exe=C:\Windows\SysWOW64\cmd.exe"

:: The FileType should always be created before making a File Association
ftype %xiseFileType%=%com32exe% /D /C call "%batchToRun%" "%bat1stPar%" "%%1" %%*
assoc .xise=%xiseFileType%

In other words: now the default action for your .xise file should be as follows (all in the only line):

C:\Windows\SysWOW64\cmd.exe /D /C call "C:\Xilinx\14.5\ISE_DS\settings32.bat" "C:\Xilinx\14.5\ISE_DS\ISE\bin\nt\ise.exe" "%1" %*

Here "%1" will expand to your "PATH\TO\XISE\FILE\filename.xise" when double-clicked.

And what about that %%* in the last ftype command? Never fear: let it be or wipe it away as it will expand to an empty string always:)

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.